Функция _GUICtrlDTP_SetFormat

         Описание функции

_GUICtrlDTP_SetFormat

Устанавливает отображаемый формат даты на основе заданного формата строки

#include <GuiDateTimePicker.au3>
_GUICtrlDTP_SetFormat($hWnd, $sFormat)

Параметры

$hWnd Дескриптор элемента
$sFormat Строка, определяющая необходимый формат даты. Установка пустой строки сбрасывает элемент в формат по умолчанию для текущего стиля. Вы можете использовать следующий формат строки:
    "d" - День указывается из одной или двух цифр
    "dd" - День указывается только из двух цифр. Одиночной цифре предшествует ноль.
    "ddd" - День недели указывается трёх-символьной аббревиатурой
    "dddd" - Полное название дня недели
    "h" - Час указывается из одной или двух цифр в 12-часовом формате
    "hh" - Час указывается только из двух цифр в 12-часовом формате
    "H" - Час указывается из одной или двух цифр в 24-часовом формате
    "HH" - Час указывается только из двух цифр в 24-часовом формате
    "m" - Минуты указываются из одной или двух цифр
    "mm" - Минуты указываются только из двух цифр
    "M" - Номер месяца указывается из одной или двух цифр
    "MM" - Номер месяца указывается только из двух цифр
    "MMM" - Месяц указывается трёх-символьной аббревиатурой
    "MMMM" - Полное название месяца
    "t" - Однобуквенная аббревиатура AM/PM
    "tt" - Двухбуквенная аббревиатура AM/PM
    "yy" - Последние две цифры года
    "yyyy" - Год, полное число

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False

Примечания

Вполне допустимо включать в форматированную строку иные символы для получения более богатого внешнего вида. Однако любые символы не соответствующие формату должны быть заключены в одинарные кавычки. Например, форматированная строка "'Сегодня: 'hh':'m':'s ddddMMMdd', 'yyy" в результате выводит "Сегодня: 04:22:42 воскресенье ноя 25, 2012". Примечание: Элемент DTP отслеживает изменения языка, когда используется форматированная строка по умолчанию. Если вы установите пользовательскую форматированную строку, он уже не будет обновляться в ответ на изменения языка.

Пример

#include <GUIConstantsEx.au3>
#include <GuiDateTimePicker.au3>

$Debug_DTP = False ; Проверяет ClassName передаваемый в DTP функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()
    Local $hDTP

    ; Создаёт GUI
    GUICreate("Устанавливает формат строки", 400, 300)
    $hDTP = GUICtrlGetHandle(GUICtrlCreateDate("", 2, 6, 190))

    GUISetState()

    ; Устанавливает формат строки
    _GUICtrlDTP_SetFormat($hDTP, "ddd MMM dd, yyyy hh:mm ttt")

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main