Функция GUICtrlCreateDate

GUICtrlCreateDate

Создаёт элемент содержащий дату и время.

GUICtrlCreateDate ( "text", left, top [, width [, height [, style = -1 [, exStyle = -1 ]]]] )

Параметры

text	Установка даты (формат всегда как "yyyy/mm/dd").
left	Координата левого края. Если -1 - тогда координата в соответствии с GUICoordMode.
top	Координата верхнего края. Если -1 - тогда координата в соответствии с GUICoordMode.
width	[необязательный] Ширина элемента (по умолчанию предыдущее значение).
height	[необязательный] Высота элемента (по умолчанию предыдущее значение).
style	[необязательный] Стиль элемента. Смотрите Стили элементов GUI в приложении. -1 - по умолчанию : $DTS_LONGDATEFORMAT принудительный стиль : $WS_TABSTOP
exStyle	[необязательный] Расширенный стиль элемента. Смотрите таблицу расширенных стилей. -1 - по умолчанию : $WS_EX_CLIENTEDGE

Возвращаемое значение

Успех:	Возвращает идентификатор (controlID) нового элемента.
Ошибка:	Возвращает 0.

Примечания

Для получения параметров элемента смотрите GUICtrlRead.
Чтобы установить или изменить параметры элемента смотрите GUICtrlUpdate....

Чтобы объединить стили со стилем по умолчанию используйте BitOR($GUI_SS_DEFAULT_DATE, новый стиль,...).

Для вывода форматированной даты / времени смотрите пример 3, чтобы понять, как использовать GUICtrlSendMsg с $DTM_SETFORMAT.

Чтобы использовать параметры, указанные выше, вы должны включить в ваш скрипт #include <DateTimeConstants.au3> in your script.

По умолчанию стиль изменения размеров $GUI_DOCKHEIGHT (не изменяется высота).

См. также

GUICoordMode (Опция), GUICtrlSetState, GUIGetMsg, GUICtrlRead

Пример

#include <GUIConstantsEx.au3>
#include <DateTimeConstants.au3>

; Opt('MustDeclareVars', 1) ; принуждает объявлять все переменные

Example1()
Example2()
Example3()
Example4()

; Пример 1
Func Example1()
Local $date, $msg

GUICreate("Дата", 200, 200, 800, 200)
$date = GUICtrlCreateDate("1953/04/25", 10, 10, 185, 20)
GUISetState()

; Запускается цикл опроса GUI до тех пор пока окно не будет закрыто
Do
$msg = GUIGetMsg()
Until $msg = $GUI_EVENT_CLOSE

MsgBox(4096, "Дата", GUICtrlRead($date))
GUIDelete()
EndFunc

; Пример 2
Func Example2()
Local $n, $msg

GUICreate("Дата", 200, 200, 800, 200)
$n = GUICtrlCreateDate("", 10, 10, 100, 20, $DTS_SHORTDATEFORMAT)
GUISetState()

; Запускается цикл опроса GUI до тех пор пока окно не будет закрыто
Do
$msg = GUIGetMsg()
Until $msg = $GUI_EVENT_CLOSE

MsgBox(4096, "Дата", GUICtrlRead($n))
GUIDelete()
EndFunc

; Пример 3
Func Example3()
Local $date, $DTM_SETFORMAT_, $style

GUICreate("Дата", 200, 200, 800, 200)
$date = GUICtrlCreateDate("1953/04/25", 10, 10, 185, 20)

; для выбора определённого формата по умолчанию
$DTM_SETFORMAT_ = 0x1032 ; $DTM_SETFORMATW
$style = "yyyy/MM/dd HH:mm:ss"
GUICtrlSendMsg($date, $DTM_SETFORMAT_, 0, $style)

GUISetState()
While GUIGetMsg() <> $GUI_EVENT_CLOSE
WEnd

MsgBox(4096, "Время", GUICtrlRead($date))
EndFunc

; Пример 4
Func Example4()
Local $n, $msg

GUICreate("Время", 200, 200, 800, 200)
$n = GUICtrlCreateDate("", 20, 20, 100, 20, $DTS_TIMEFORMAT)
GUISetState()

; Запускается цикл опроса GUI до тех пор пока окно не будет закрыто
Do
$msg = GUIGetMsg()
Until $msg = $GUI_EVENT_CLOSE

MsgBox(4096, "Время", GUICtrlRead($n))
GUIDelete()
EndFunc