Функция _GUICtrlComboBoxEx_SetTopIndex

         Описание функции

_GUICtrlComboBoxEx_SetTopIndex

Обеспечивает, чтобы указанный пункт находился в видимой области списка ComboBox

#include <GuiComboBoxEx.au3>
_GUICtrlComboBoxEx_SetTopIndex($hWnd, $iIndex)

Параметры

$hWnd Дескриптор элемента
$iIndex Индекс пункта, отсчёт от 0.

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False

Примечания

Система прокручивает содержимое списка так, чтобы указанный пункт оказался наверху видимой части списка или максимально прокручивает, чтобы достигнуть этого.

См. также

_GUICtrlComboBoxEx_GetTopIndex

Пример

#include <GuiComboBoxEx.au3>
#include <GUIConstantsEx.au3>

$Debug_CB = False ; Проверяет ClassName передаваемый в ComboBox/ComboBoxEx функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()
    Local $hGUI, $hCombo

    ; Создаёт GUI
    $hGUI = GUICreate("Устанавливает верхний пункт", 400, 300)
    $hCombo = _GUICtrlComboBoxEx_Create ($hGUI, "", 2, 2, 394, 100, $CBS_SIMPLE)
    GUISetState()

    _GUICtrlComboBoxEx_InitStorage ($hCombo, 150, 300)
    _GUICtrlComboBoxEx_BeginUpdate ($hCombo)

    For $x = 0 To 149
        _GUICtrlComboBoxEx_AddString ($hCombo, StringFormat("%03d : Рандомная строка", Random(1, 100, 1)))
    Next
    _GUICtrlComboBoxEx_EndUpdate ($hCombo)

    ; Устанавливает верхний пункт
    MsgBox(4160, "Информация", "Успех установки верхнего пункта: " & _GUICtrlComboBoxEx_SetTopIndex ($hCombo, Random(50, 149, 1)) & @CRLF & _
    "Индекс верхнего пункта: " & _GUICtrlComboBoxEx_GetTopIndex ($hCombo))

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>_Main