Функция _GUICtrlComboBoxEx

Функция _GUICtrlComboBoxEx_SetEditSel

_GUICtrlComboBoxEx_SetEditSel

Выделяет символы в поле ввода ComboBox

#include <GuiComboBoxEx.au3>
_GUICtrlComboBoxEx_SetEditSel($hWnd, $iStart, $iStop)

Параметры

$hWnd	Дескриптор элемента
$iStart	Позиция начального символа
$iStop	Позиция конечного символа

Возвращаемое значение

Успех:	Возвращает True
Ошибка:	False, если сообщение высылается ComboBox со стилем $CBS_DROPDOWN или $CBS_DROPDOWNLIST

Примечания

Отсчёт от 0. Первый символ поля ввода имеет позицию 0.
Если $iStop = -1, то будет выделен весь текст от указанной начальной позиции до последнего символа в поле ввода.

The first character after the last selected character is in the ending position.

Например, чтобы выделить первые четыре символа в поле ввода, используйте начальную позицию 0 и конечную позицию 4.

См. также

_GUICtrlComboBox_GetEditSel, _GUICtrlComboBoxEx_GetEditSel

Пример

#include <GuiComboBoxEx.au3>
#include <GuiImageList.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

$Debug_CB = False ; Проверяет ClassName передаваемый в ComboBox/ComboBoxEx функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

Global $iMemo

_Main()

Func _Main()
Local $hGUI, $hImage, $aSel, $hCombo

; Создаёт GUI
$hGUI = GUICreate("Выделяет часть текста в поле ввода", 400, 300)
$hCombo = _GUICtrlComboBoxEx_Create ($hGUI, "", 2, 2, 394, 70, BitOR($CBS_SIMPLE, $WS_VSCROLL, $WS_BORDER))
$iMemo = GUICtrlCreateEdit("", 2, 72, 396, 226, 0)
GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
GUISetState()

$hImage = _GUIImageList_Create (16, 16, 5, 3)
_GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 110)
_GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 131)
_GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 165)
_GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 168)
_GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 137)
_GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 146)
_GUIImageList_Add ($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap ($hCombo, 0xFF0000, 16, 16))
_GUIImageList_Add ($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap ($hCombo, 0x00FF00, 16, 16))
_GUIImageList_Add ($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap ($hCombo, 0x0000FF, 16, 16))
_GUICtrlComboBoxEx_SetImageList ($hCombo, $hImage)

; Добавляет строки
For $x = 0 To 8
_GUICtrlComboBoxEx_AddString ($hCombo, StringFormat("%03d : Рандомная строка", Random(1, 100, 1)), $x, $x)
Next

; Выбирает пункт
_GUICtrlComboBoxEx_SetCurSel ($hCombo, Random(0, 8, 1))

; Выделяет часть текста в поле ввода
_GUICtrlComboBoxEx_SetEditSel ($hCombo, 0, 4)

; Получает позиции выделенного
$aSel = _GUICtrlComboBoxEx_GetEditSel ($hCombo)
MemoWrite(StringFormat("Позиции выделенного: [%d][%d]", $aSel[0], $aSel[1]))

Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc ;==>_Main

; Записывает строку в элемент для заметок
Func MemoWrite($sMessage)
GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc ;==>MemoWrite