Функция _GUICtrlComboBoxEx_SetDroppedWidth

         Описание функции

_GUICtrlComboBoxEx_SetDroppedWidth

Устанавливает максимально допустимую ширину выпадающего списка ComboBox в пикселях

#include <GuiComboBoxEx.au3>
_GUICtrlComboBoxEx_SetDroppedWidth($hWnd, $iWidth)

Параметры

$hWnd Дескриптор элемента
$iWidth Ширина выпадающего списка в пикселях

Возвращаемое значение

Успех:Возвращает новую ширину списка
Ошибка:Возвращает -1

Примечания

По умолчанию минимально допустимая ширина выпадающего списка равна 0. Ширина списка равна либо минимально допустимой, либо ширине ComboBox, если его ширина больше.

Используйте стили $CBS_DROPDOWN или $CBS_DROPDOWNLIST.

См. также

_GUICtrlComboBoxEx_GetDroppedWidth

Пример

#include <GuiComboBoxEx.au3>
#include <GuiImageList.au3>
#include <GUIConstantsEx.au3>

$Debug_CB = False ; Проверяет ClassName передаваемый в ComboBox/ComboBoxEx функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

Global $iMemo

_Main()

Func _Main()
    Local $hGUI, $hImage, $hCombo

    ; Создаёт GUI
    $hGUI = GUICreate("Устанавливает ширину выпадающего списка", 400, 300)
    $hCombo = _GUICtrlComboBoxEx_Create ($hGUI, "", 2, 2, 394, 100)
    $iMemo = GUICtrlCreateEdit("", 2, 32, 396, 266, 0)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    $hImage = _GUIImageList_Create (16, 16, 5, 3)
    _GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 110)
    _GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 131)
    _GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 165)
    _GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 168)
    _GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 137)
    _GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 146)
    _GUIImageList_Add ($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap ($hCombo, 0xFF0000, 16, 16))
    _GUIImageList_Add ($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap ($hCombo, 0x00FF00, 16, 16))
    _GUIImageList_Add ($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap ($hCombo, 0x0000FF, 16, 16))
    _GUICtrlComboBoxEx_SetImageList ($hCombo, $hImage)

    For $x = 0 To 8
        _GUICtrlComboBoxEx_AddString ($hCombo, StringFormat("%03d : Рандомная строка", Random(1, 100, 1)), $x, $x)
    Next

    ; Возвращает ширину выпадающего списка
    ; Она может отличаться от ширины ComboBox
    MemoWrite("Ширина выпадающего списка: " & _GUICtrlComboBoxEx_GetDroppedWidth ($hCombo))

    Sleep(500)

    ; Раскрывает список
    _GUICtrlComboBoxEx_ShowDropDown ($hCombo, True)

    Sleep(500)

    ; Сворачивает список
    _GUICtrlComboBoxEx_ShowDropDown ($hCombo)

    ; Устанавливает ширину выпадающего списка
    _GUICtrlComboBoxEx_SetDroppedWidth ($hCombo, 500)

    Sleep(500)

    ; Возвращает ширину выпадающего списка
    MemoWrite("Ширина выпадающего списка: " & _GUICtrlComboBoxEx_GetDroppedWidth ($hCombo))

    Sleep(500)

    ; Раскрывает список
    _GUICtrlComboBoxEx_ShowDropDown ($hCombo, True)

    Sleep(500)

    ; Сворачивает список
    _GUICtrlComboBoxEx_ShowDropDown ($hCombo)

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main

; Записывает строку в элемент для заметок
Func MemoWrite($sMessage)
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite