Функция _GUICtrlComboBoxEx

Функция _GUICtrlComboBoxEx_GetEditText

_GUICtrlComboBoxEx_GetEditText

Возвращает текст из поля редактирования ComboBoxEx

#include <GuiComboBoxEx.au3>
_GUICtrlComboBoxEx_GetEditText($hWnd)

Параметры

$hWnd

Дескриптор элемента

Возвращаемое значение

Успех:	Возвращает строку из поля редактирования
Ошибка:	Возвращает пустую строку

Примечания

Если сообщение высылается в ComboBox со стилем $CBS_DROPDOWN или $CBS_DROPDOWNLIST, то функция потерпит неудачу.

См. также

_GUICtrlComboBoxEx_SetEditText

Пример

#include <GuiComboBoxEx.au3>
#include <GuiImageList.au3>
#include <GUIConstantsEx.au3>

$Debug_CB = False ; Проверяет ClassName передаваемый в ComboBox/ComboBoxEx функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()
Local $hGUI, $hImage, $hCombo

; Создаёт GUI
$hGUI = GUICreate("Получает текст из поля ввода", 400, 300)
$hCombo = _GUICtrlComboBoxEx_Create ($hGUI, "", 2, 2, 394, 100, $CBS_SIMPLE)
GUISetState()

$hImage = _GUIImageList_Create (16, 16, 5, 3)
_GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 110)
_GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 131)
_GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 165)
_GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 168)
_GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 137)
_GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 146)
_GUIImageList_Add ($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap ($hCombo, 0xFF0000, 16, 16))
_GUIImageList_Add ($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap ($hCombo, 0x00FF00, 16, 16))
_GUIImageList_Add ($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap ($hCombo, 0x0000FF, 16, 16))
_GUICtrlComboBoxEx_SetImageList ($hCombo, $hImage)

For $x = 0 To 8
_GUICtrlComboBoxEx_AddString ($hCombo, StringFormat("%03d : Рандомная строка", Random(1, 100, 1)), $x, $x)
Next

; Устанавливает текст в поле ввода
_GUICtrlComboBoxEx_SetEditText ($hCombo, StringFormat("%03d : Рандомная строка", Random(1, 100, 1)))

; Получает текст из поля ввода
MsgBox(4160, "Информация", "Текст из поля ввода: " & _GUICtrlComboBoxEx_GetEditText ($hCombo))

Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc ;==>_Main