Функция _GUICtrlAVI_Open

         Описание функции

_GUICtrlAVI_Open

Открывает клип AVI и отображает его первый кадр в элементе AVI

#include <GuiAVI.au3>
_GUICtrlAVI_Open($hWnd, $sFileName)

Параметры

$hWnd Дескриптор или идентификатор элемента
$sFileName Полный путь к avi-файлу

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False

Примечания

Вы можете открыть только беззвучные клипы AVI

См. также

_GUICtrlAVI_Close, _GUICtrlAVI_OpenEx

Пример

#include <GUIConstantsEx.au3>
#include <GuiAVI.au3>

$Debug_AVI = False ; Проверяет ClassName передаваемый в AVI функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

Global $hAVI

_Main()

Func _Main()
    Local $Wow64 = ""
    If @AutoItX64 Then $Wow64 = "\Wow6432Node"
    Local $hGUI, $sFile = RegRead("HKEY_LOCAL_MACHINE\SOFTWARE" & $Wow64 & "\AutoIt v3\AutoIt", "InstallDir") & "\Examples\GUI\SampleAVI.avi"

    ; Создаёт GUI
    $hGUI = GUICreate("(UDF) Открывает AVI", 300, 100)
    $hAVI = _GUICtrlAVI_Create ($hGUI, "", -1, 10, 10)
    GUISetState()

    ; Открывает пример AutoIt AVI
    _GUICtrlAVI_Open($hAVI, $sFile)

    ; Воспроизводит пример AutoIt AVI
    _GUICtrlAVI_Play($hAVI)

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Закрывает AVI
    _GUICtrlAVI_Close($hAVI)


    GUIDelete()
EndFunc   ;==>_Main