Функция _GDIPlus_ParamInit

         Описание функции

_GDIPlus_ParamInit

Инициализирует список параметров кодировщика

#include <GDIPlus.au3>
_GDIPlus_ParamInit($iCount)

Параметры

$iCount Общее количество параметров, которые будут содержаться в списке

Возвращаемое значение

Успех:Возвращает структуру $tagGDIPPENCODERPARAMS
Ошибка:Возвращает 0

Примечания

In order to pass parameters to any of the encoder functions, you must use an encoder parameter list. This function is used to initialize an encoder parameter list that can then be passed to _GDIPlus_ParamAdd() to add the actual parameters.

См. также

_GDIPlus_ParamAdd, $tagGDIPPENCODERPARAMS

Пример

#include <GDIPlus.au3>
#include <ScreenCapture.au3>

_Main()

Func _Main()
    Local $hImage, $sCLSID, $tData, $tParams

    ; Capture screen
    _ScreenCapture_Capture (@MyDocumentsDir & "\GDIPlus_Image.jpg")

    ; Инициализация библиотеки GDI+
    _GDIPlus_Startup ()

    ; Load image
    $hImage = _GDIPlus_ImageLoadFromFile (@MyDocumentsDir & "\GDIPlus_Image.jpg")

    ; Get JPEG encoder CLSID
    $sCLSID = _GDIPlus_EncodersGetCLSID ("JPG")

    ; Set up parameters for 90 degree rotation
    $tData = DllStructCreate("int Data")
    DllStructSetData($tData, "Data", $GDIP_EVTTRANSFORMROTATE90)
    $tParams = _GDIPlus_ParamInit (1)
    _GDIPlus_ParamAdd ($tParams, $GDIP_EPGTRANSFORMATION, 1, $GDIP_EPTLONG, DllStructGetPtr($tData, "Data"))

    ; Save image with rotation
    _GDIPlus_ImageSaveToFileEx ($hImage, @MyDocumentsDir & "\GDIPlus_Image2.jpg", $sCLSID, DllStructGetPtr($tParams))

    ; Закрывает библиотеку GDI+
    _GDIPlus_ShutDown ()

EndFunc   ;==>_Main