Функция _GDIPlus_ImageSaveToFileEx

         Описание функции

_GDIPlus_ImageSaveToFileEx

Сохраняет изображение в файл

#include <GDIPlus.au3>
_GDIPlus_ImageSaveToFileEx($hImage, $sFileName, $sEncoder [, $pParams = 0])

Параметры

$hImage Дескриптор объекта изображения
$sFileName Полный путь к файлу изображения
$sEncoder Строка GUID кодировщика, который будет использоваться
$pParams [необязательный] Указатель на структуру $tagGDIPPENCODERPARAMS

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False

См. также

_GDIPlus_ImageLoadFromFile, _GDIPlus_ImageSaveToFile, $tagGDIPPENCODERPARAMS

См. также

Искать GdipSaveImageToFile в библиотеке MSDN

Пример

#include <GDIPlus.au3>
#include <ScreenCapture.au3>

_Main()

Func _Main()
    Local $hImage, $sCLSID, $tData, $tParams

    ; Capture screen
    _ScreenCapture_Capture (@MyDocumentsDir & "\GDIPlus_Image.jpg")

    ; Инициализация библиотеки GDI+
    _GDIPlus_Startup ()

    ; Load image
    $hImage = _GDIPlus_ImageLoadFromFile (@MyDocumentsDir & "\GDIPlus_Image.jpg")

    ; Get JPEG encoder CLSID
    $sCLSID = _GDIPlus_EncodersGetCLSID ("JPG")

    ; Set up parameters for 90 degree rotation
    $tData = DllStructCreate("int Data")
    DllStructSetData($tData, "Data", $GDIP_EVTTRANSFORMROTATE90)
    $tParams = _GDIPlus_ParamInit (1)
    _GDIPlus_ParamAdd ($tParams, $GDIP_EPGTRANSFORMATION, 1, $GDIP_EPTLONG, DllStructGetPtr($tData, "Data"))

    ; Save image with rotation
    _GDIPlus_ImageSaveToFileEx ($hImage, @MyDocumentsDir & "\GDIPlus_Image2.jpg", $sCLSID, DllStructGetPtr($tParams))

    ; Закрывает библиотеку GDI+
    _GDIPlus_ShutDown ()

EndFunc   ;==>_Main