Функция _GDIPlus

Функция _GDIPlus_ImageGetFlags

_GDIPlus_ImageGetFlags

Returns enumeration of pixel data attributes contained in an image

#include <GDIPlus.au3>
_GDIPlus_ImageGetFlags($hImage)

Параметры

$hImage

Дескриптор объекта изображения

Возвращаемое значение

Успех:	Возвращает массив следующего формата:
	[0] - - Integer flag set of pixel data attributes
	[1] - - String of pixel data attributes separated by delimiter "\|"
Ошибка:	Возвращает пустой массив и устанавливает @error, @extended содержит местную ошибку функции
@error:	0 - Нет ошибок.
	10 - Неверный дескриптор изображения

Примечания

@error 4 основывается на возвращении функцией GDI+ UDF значений -1 или 0, как ошибка, вместо возвращения дескриптора изображения
Use BitAND on returned integer flag set with GdipGetImageFlags constants

См. также

_GDIPlus_ImageGetPixelFormat

См. также

Искать GdipGetImageFlags в библиотеке MSDN

Пример

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GDIPlus.au3>
#include <ScreenCapture.au3>
#include <WinAPI.au3>

Global $iMemo

_Main()

Func _Main()
Local $hBitmap, $hImage, $aRet

; Создаёт GUI
GUICreate("GDI+", 600, 400)
$iMemo = GUICtrlCreateEdit("", 2, 2, 596, 396, $WS_VSCROLL)
GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
GUISetState()

; Инициализация библиотеки GDI+
_GDIPlus_Startup()

; Capture 32 bit bitmap
$hBitmap = _ScreenCapture_Capture("")
$hImage = _GDIPlus_BitmapCreateFromHBITMAP($hBitmap)

; Show enumeration of pixel data attributes for screen capture
$aRet = _GDIPlus_ImageGetFlags($hImage)
$aRet[1] = @CRLF & StringReplace($aRet[1], "|", @CRLF)
MemoWrite("Image pixel data attributes of screen capture: " & $aRet[1]);
MemoWrite();
MemoWrite("Image flag set of pixel data attributes: " & $aRet[0]);
MemoWrite();

; Save screen capture bitmap to file
_GDIPlus_ImageSaveToFile($hImage, @MyDocumentsDir & "\GDIPlus_Image.jpg")

; Очищает ресурсы
_GDIPlus_ImageDispose($hImage)
_WinAPI_DeleteObject($hBitmap)

; Load screen capture bitmap from file
$hImage = _GDIPlus_ImageLoadFromFile(@MyDocumentsDir & "\GDIPlus_Image.jpg")

; Show enumeration of pixel data attributes for saved file
$aRet = _GDIPlus_ImageGetFlags($hImage)
$aRet[1] = @CRLF & StringReplace($aRet[1], "|", @CRLF)
MemoWrite("Image pixel data attributes of saved file: " & $aRet[1]);
MemoWrite();
MemoWrite("Image flag set of pixel data attributes: " & $aRet[0]);

; Очищает ресурсы
_GDIPlus_ImageDispose($hImage)

; Закрывает библиотеку GDI+
_GDIPlus_Shutdown()

; Цикл выполняется, пока окно не будет закрыто
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE

EndFunc ;==>_Main

; Записывает строку в элемент для заметок
Func MemoWrite($sMessage = '')
GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc ;==>MemoWrite