Описание функции Описание функции
_GDIPlus_DrawImagePoints
Рисует изображение в указанном месте.
#include <GDIPlus.au3>
_GDIPlus_DrawImagePoints($hGraphic, $hImage, $nULX, $nULY, $nURX, $nURY, $nLLX, $nLLY [, $count = 3])
Параметры
| $hGraphic | Дескриптор графического объекта |
| $hImage |
Дескриптор объекта изображения |
| $nULX |
X координата левого верхнего угла исходного изображения |
| $nULY |
Y координата левого верхнего угла исходного изображения |
| $nURX |
X координата правого верхнего угла исходного изображения |
| $nURY |
Y координата правого верхнего угла исходного изображения |
| $nLLX |
X координата левого нижнего угла исходного изображения |
| $nLLY |
Y координата левого нижнего угла исходного изображения |
| $count |
[необязательный] Указывает количество точек (x,y) в структуре. |
Возвращаемое значение
| Успех: | Возвращает True |
| Ошибка: | Возвращает False |
Примечания
Значение параметра "$count" должно быть равно 3, чтобы задать координаты левого верхнего угла, правого верхнего угла, и левого нижнего угла параллелограмма. Координата правого нижнего угла, ширина и высота изображения рассчитываются с использованием трех указанных координат. Изображение масштабируется по размерам параллелограмма.См. также
Искать GdipDrawImagePoints в библиотеке MSDNПример
#include <GDIPlus.au3>
#include <ScreenCapture.au3>
_Main()
Func _Main()
Local $hBitmap1, $hBitmap2, $hImage1, $hImage2, $hGraphic
; Инициализация библиотеки GDI+
_GDIPlus_Startup()
; Захватывает весь экран
$hBitmap1 = _ScreenCapture_Capture("")
$hImage1 = _GDIPlus_BitmapCreateFromHBITMAP($hBitmap1)
; Захватывает область экрана
$hBitmap2 = _ScreenCapture_Capture("", 0, 0, 400, 300)
$hImage2 = _GDIPlus_BitmapCreateFromHBITMAP($hBitmap2)
; Рисует одно изображение в другом
$hGraphic = _GDIPlus_ImageGetGraphicsContext($hImage1)
_GDIPlus_DrawImagePoints($hGraphic, $hImage2, 100, 100, 600, 170, 130, 570)
; Рисует рамку вокруг вставленного изображения
_GDIPlus_GraphicsDrawRect($hGraphic, 100, 100, 400, 300)
; Сохраняет изображение в файл
_GDIPlus_ImageSaveToFile($hImage1, @MyDocumentsDir & "\GDIPlus_Image.jpg")
; Очищает ресурсы
_GDIPlus_ImageDispose($hImage1)
_GDIPlus_ImageDispose($hImage2)
_WinAPI_DeleteObject($hBitmap1)
_WinAPI_DeleteObject($hBitmap2)
; Закрывает библиотеку GDI+
_GDIPlus_Shutdown()
EndFunc ;==>_Main