Функция GUICtrlSetTip

         Описание функции

GUICtrlSetTip

Устанавливает всплывающую подсказку элементу управления.

GUICtrlSetTip ( controlID, tiptext [, "title" [, icon [, options ]]] )

Параметры

controlID Идентификатор элемента возвращаемый функцией GUICtrlCreate....
tiptext Текст всплывающей подсказки, который отображается при наведении мыши на элемент интерфейса.
title [необязательный] Заголовок подсказки Требуется IE5+
icon [необязательный] Иконка, которая будет отображаться рядом с заголовком: Требуется IE5+. Требуется заголовок.
    0 = Без иконки
    1 = Информационная иконка
    2 = Иконка предупреждения
    3 = Иконка ошибки
options [необязательный] Установка различных параметров способа отображения подсказки (Может быть сложено - 1+2):
    1 = Овальная подсказка Требуется IE5+
    2 = Подсказка центрированная по горизонтали вдоль элемента.

Возвращаемое значение

Успех:Возвращает 1.
Ошибка:Возвращает 0.

Примечания

Этот текст отображается в подсказке прямоугольной области.
Чтобы пропустить необязательный параметр, оставляя это значение по умолчанию, используйте ключевое слово Default.
Используя @CR или @LF вы можете создать подсказку в несколько строк.
Заголовок подсказки, иконка и округлый вид требуют Internet Explorer 5.0 или более поздней версии.
Для отображения иконки, вы должны указать непустой заголовок. Иконка отображается в той же строке, что и заголовок, поэтому требует его наличия.

См. также

GUICtrlUpdate...

Пример

#include <WinAPI.au3> ; для своей иконки

GUICreate("Подсказки", 220, 220)

$Button = GUICtrlCreateButton('Кнопка', 50, 10, 120, 27)
GUICtrlSetTip($Button, 'Овальная подсказка (options 1), от мыши', 'Заголовок, иконка 2', 2, 1)

GUICtrlCreateCombo("", 50, 45, 120, -1, 0x3) ; $CBS_DROPDOWNLIST = 0x3 - стиль не редактируемого списка
GUICtrlSetData(-1, "не редактируемый|элемент2|элемент3|элемент4", "не редактируемый")
GUICtrlSetTip(-1, 'Овальная симметрично элементу (options 3)', 'Заголовок, иконка 1', 1, 3)

; Получает дескриптор иконки
$hIcon = _WinAPI_LoadShell32Icon(15) ; также _WinAPI_ExtractIconEx
GUICtrlCreateLabel('Подсказка к тексту', 50, 80, 120, 17)
GUICtrlSetTip(-1, 'Выпадающая вниз, симметрично элементу (options 2)', 'Заголовок, своя иконка', $hIcon, 2)

GUICtrlCreateCheckbox('CheckBox', 50, 105, 120, 17)
GUICtrlSetTip(-1, 'Выпадающая вниз, от мыши', 'Заголовок, иконка 3', 3)

GUICtrlCreateSlider(40, 130, 120, 30)
GUICtrlSetTip(-1, 'Без иконки', 'Заголовок')

GUICtrlCreateRadio('Радиокнопка', 50, 170, 120, 17)
GUICtrlSetTip(-1, 'Без заголовка')

GUISetState()
Do
Until GUIGetMsg() = -3