Функция GUICtrlSetBkColor

GUICtrlSetBkColor

Устанавливает фоновый цвет элемента.

GUICtrlSetBkColor ( controlID, backgroundcolor )

Параметры

controlID	Идентификатор элемента возвращаемый функцией GUICtrlCreate....
backgroundcolor	Цвет в формате RGB (шестнадцатеричного или десятичного числа).

Возвращаемое значение

Успех:	Возвращает 1.
Ошибка:	Возвращает 0.

Примечания

Устанавливается только для элементов Button, Label, Checkbox, Group, Radio, Edit, Input, List, Listview, ListviewItem, Treeview, TreeviewItem, Graphic, Progress, Slider и Combo.

Элементы Checkbox, Radio, Group, Progress, Combo могут быть окрашены, если используется классический стиль.

Кнопки при окрашивании автоматически переключаются в классический стиль Windows. Они не могут иметь стиль $BS_ICON.

Специальный флаг $GUI_BKCOLOR_TRANSPARENT (вместо цвета) может использоваться с элементами Label, Group, Radio, Checkbox, чтобы дать элементам прозрачный фон.

Специальный флаг $GUI_BKCOLOR_LV_ALTERNATE может быть использован с элементом Listview чтобы дать альтернативный фон пунктам ListviewItems.
Нечётные строки получите установкой цвета GUICtrlSetBkColor для Listview.
Чётные строки получите установкой цвета GUICtrlSetBkColor для ListviewItem.

См. также

GUICtrlCreate..., GUICtrlSetColor, GUICtrlSetDefBkColor

Пример

#include <GUIConstantsEx.au3>

Example()

Func Example()
Local $msg, $ProgressBar

GUICreate("Цвет фона элементов GUI") ; Создаёт окно в центре экрана

GUICtrlCreateLabel("Зелёный фон", 10, 20)
GUICtrlSetBkColor(-1, 0xCCFFCC) ; Светло-зелёный

$ProgressBar = GUICtrlCreateProgress(10, 60, 200, 20)
; Применяет к $ProgressBar классический стиль, чтобы окрасить элемент
DllCall("UxTheme.dll", "int", "SetWindowTheme", "hwnd", GUICtrlGetHandle($ProgressBar), "wstr", 0, "wstr", 0)
GUICtrlSetColor(-1, 0x0080FF) ; Лазурный
GUICtrlSetBkColor(-1, 0xFDFFAE)
GUICtrlSetData(-1, 50)

GUISetState()

; Запускается цикл опроса GUI до тех пор пока окно не будет закрыто
While 1
$msg = GUIGetMsg()

If $msg = $GUI_EVENT_CLOSE Then ExitLoop
WEnd
EndFunc