Функция _GDIPlus_PathBrushCreateFromPath

_GDIPlus_PathBrushCreateFromPath

Создаёт объект PathGradientBrush основанный на объекте GraphicsPath

#Include <GDIP.au3>
_GDIPlus_PathBrushCreateFromPath($hPath)

Параметры

$hPath

Указатель на объект GraphicsPath, который определяет границы кисти градиента

Возвращаемое значение

Успех:	Возвращает указатель на новый объект PathGradientBrush
Ошибка:	Возвращает 0, либо:
	Если ошибка DllCall(), устанавливает @error и @extended возвращённые вызовом DllCall()
	$GDIP_STATUS содержит не нулевое значение кода ошибки

Примечания

После завершения использования объекта вызовите _GDIPlus_BrushDispose, чтобы освободить ресурсы объекта

См. также

Искать GdipCreatePathGradientFromPath в библиотеке MSDN

Пример

#include <GDIP.au3>
#include <GUIConstantsEx.au3>

_Example()

Func _Example()
Local $hGUI, $hGraphics, $hPath, $hBrush
Local $aColors[11] = [10, 0xFFFF0000, 0xFFFF0000, 0xFF0000FF, 0xFFFF0000, 0xFFFF0000, 0xFF0000FF, 0xFFFF0000, 0xFFFFFFFF, 0xFFFF0000, 0xFF0000FF]
; Local $aPoints[11][2] = [[10], [0, 100], [130, 100], [200, 0], [270, 100], [400, 100], [300, 150], [400, 300], [200, 200], [0, 300], [100, 150]]
Local $aPoints[11][2] = [[10], [303, 114], [215, 178], [248, 281], [160, 218], [72, 281], [105, 178], [17, 114], [126, 113], [160, 10], [194, 113]]

; Инициализирует библиотеку GDI+
_GDIPlus_Startup()

$hGUI = GUICreate("_GDIPlus_PathBrushCreateFromPath", 400, 300)
GUISetState()

; Создаёт графический объект из дескриптора окна
$hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGUI)

; Создаёт объект GraphicsPath
$hPath = _GDIPlus_PathCreate()
; Добавляет линии, созданные из массива точек
_GDIPlus_PathAddLines($hPath, $aPoints)

; Создаёт кисть градиента на основе GraphicsPath
$hBrush = _GDIPlus_PathBrushCreateFromPath($hPath)
; Устанавливает цвет центра кисти градиента
_GDIPlus_PathBrushSetCenterColor($hBrush, 0xFF00FF00)
; Устанавливает цвета окружения кисти градиента
_GDIPlus_PathBrushSetSurroundColorsWithCount($hBrush, $aColors)

; Заполняет объект Path кистью
_GDIPlus_GraphicsFillPath($hGraphics, $hPath, $hBrush)

Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE

; Освобождает ресурсы
_GDIPlus_BrushDispose($hBrush)
_GDIPlus_PathDispose($hPath)
_GDIPlus_GraphicsDispose($hGraphics)

; Закрывает библиотеку GDI+
_GDIPlus_Shutdown()
EndFunc