Функция _GDIPlus_PathBrushSetSurroundColorsWithCount

         Описание функции

_GDIPlus_PathBrushSetSurroundColorsWithCount

Устанавливает цвета окружения кисти градиента

#Include <GDIP.au3>
_GDIPlus_PathBrushSetSurroundColorsWithCount($hPathGradientBrush, $aColors)

Параметры

$hPathGradientBrush Указатель на объект PathGradientBrush
$aColors Массив, содержащий окружающие цвета:
[0] - Количество цветов
[1] - Цвет 1
[2] - Цвет 2
[n] - Цвет n

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False и либо:
Если ошибка DllCall(), устанавливает @error и @extended возвращённые вызовом DllCall()
$GDIP_STATUS содержит не нулевое значение кода ошибки
$GDIP_ERROR:
1 - Сбой функции _GDIPlus_PathBrushGetSurroundColorCount, $GDIP_STATUS содержит код ошибки
2 - Объект PathGradientBrush не содержит никаких окружающих цветов
3 - Количество цветов возвращаемых в массив больше, чем число точек в кисти
4 - Сбой функции _GDIPlus_PathBrushGetSurroundColorsWithCount, $GDIP_STATUS содержит код ошибки

Примечания

Окружающие цвета являются цвета, которые указанны для дискретных точек на границах кисти

См. также

_GDIPlus_PathBrushGetSurroundColorsWithCount

См. также

Искать GdipSetPathGradientSurroundColorsWithCount в библиотеке MSDN

Пример

#include <GDIP.au3>
#include <GUIConstantsEx.au3>

_Example()

Func _Example()
    Local $hGUI, $hGraphics, $hBrush
    Local $aColors[11] = [10, 0xFFFF0000, 0xFFFF0000, 0xFF0000FF, 0xFFFF0000, 0xFFFF0000, 0xFF0000FF, 0xFFFF0000, 0xFFFFFFFF, 0xFFFF0000, 0xFF0000FF]
    ; Local $aPoints[11][2] = [[10], [0, 100], [130, 100], [200, 0], [270, 100], [400, 100], [300, 150], [400, 300], [200, 200], [0, 300], [100, 150]]
    Local $aPoints[11][2] = [[10], [303, 114], [215, 178], [248, 281], [160, 218], [72, 281], [105, 178], [17, 114], [126, 113], [160, 10], [194, 113]]

    ; Инициализирует библиотеку GDI+
    _GDIPlus_Startup()

    $hGUI = GUICreate("_GDIPlus_PathBrushCreate", 400, 300)
    GUISetState()

    ; Создаёт графический объект из дескриптора окна
    $hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGUI)

    ; Создаёт путь кисти градиента из точек
    $hBrush = _GDIPlus_PathBrushCreate($aPoints)
    ; Устанавливает цвет центра кисти градиента
    _GDIPlus_PathBrushSetCenterColor($hBrush, 0xFF00FF00)
    ; Устанавливает цвета окружения кисти градиента
    _GDIPlus_PathBrushSetSurroundColorsWithCount($hBrush, $aColors)

    ; Заполняет многоугольник используя кисть градиента
    _GDIPlus_GraphicsFillPolygon($hGraphics, $aPoints, $hBrush)

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Освобождает ресурсы
    _GDIPlus_BrushDispose($hBrush)
    _GDIPlus_GraphicsDispose($hGraphics)

    ; Закрывает библиотеку GDI+
    _GDIPlus_Shutdown()
EndFunc