_WordDocAddPicture
Добавляет рисунок в документ
#include <Word.au3>
_WordDocAddPicture(ByRef $o_object, $s_FilePath [, $b_LinkToFile = 0 [, $b_SaveWithDocument = 0 [, $o_Range = ""]]])
Параметры
| $o_object | Переменная объекта документа Word.Application |
| $s_FilePath |
Путь к файлу рисунка. |
| $b_LinkToFile |
[необязательный] Specifies whether to link the picture to the file from which it was created. 0 = (по умолчанию) Делает рисунок независимой копией файла 1 = Link the picture to the file from which it was created |
| $b_SaveWithDocument |
[необязательный] Specifies whether to save the linked picture with the document. 0 = (по умолчанию) Do not save the linked picture with the document 1 = Save the linked picture with the document |
| $o_Range |
[необязательный] Место, где картина будет размещаться в тексте. "" = (по умолчанию) Рисунок размещается автоматически Любой объект диапазона |
Возвращаемое значение
| Успех: | Возвращает переменную объекта, указывающую на объект рисунка Word.Application |
| Ошибка: | Возвращает 0 и устанавливает @error = 1 |
| @error: | $_WordStatus_Success = Нет ошибок |
| $_WordStatus_GeneralError = Общая ошибка | |
| $_WordStatus_ComError = Com ошибка | |
| $_WordStatus_InvalidDataType = Неверный тип данных | |
| $_WordStatus_InvalidObjectType = Неверный тип объекта | |
| $_WordStatus_InvalidValue = Неверное значение | |
| @extended: | Содержит номер неисправного параметра |
Пример
; *******************************************************
; Пример 1 - Create a word window with a new blank document,
; then add some pictures to the document.
; *******************************************************
#include <Word.au3>
$sPath = @WindowsDir & "\"
$search = FileFindFirstFile($sPath & "*.bmp")
; Check if the search was successful
If $search = -1 Then
MsgBox(4096, "Error", "No images found")
Exit
EndIf
$oWordApp = _WordCreate ()
$oDoc = _WordDocGetCollection ($oWordApp, 0)
While 1
$file = FileFindNextFile($search)
If @error Then ExitLoop
$oShape = _WordDocAddPicture ($oDoc, $sPath & $file, 0, 1)
If Not @error Then $oShape.Range.InsertAfter (@CRLF)
WEnd
; Close the search handle
FileClose($search)