↑  ←  Описание функции

_GUIToolTip_GetToolCount

Возвращает количество подсказок в ToolTip

#include <GuiToolTip.au3>
_GUIToolTip_GetToolCount($hWnd)

Параметры

Возвращаемое значение

Пример

#include <GUIConstantsEx.au3>
#include <GUIToolTip.au3>

Example()

Func Example()
    Local $hGUI, $hToolTip, $iDel, $iClose, $hDel, $hClose

    $hGUI = GUICreate(StringTrimRight(@ScriptName, 4))

    $iDel = GUICtrlCreateButton("Удалить подсказку", 80, 50, 110, 28)
    $hDel = GUICtrlGetHandle(-1) ; Получает дескриптор элемента, чтобы использовать для ToolTip
    $iClose = GUICtrlCreateButton("Кнопка выхода", 80, 90, 110, 28)
    $hClose = GUICtrlGetHandle($iClose)

    $hToolTip = _GUIToolTip_Create($hGUI, $TTS_BALLOON) ; Создаёт стиль овальной подсказки

    ; Назначает подсказку элементу
    _GUIToolTip_AddTool($hToolTip, $hGUI, "Подсказка", $hDel, 0, 0, 0, 0, 9)
    _GUIToolTip_AddTool($hToolTip, $hGUI, "Это кнопка завершения скрипта", $hClose, 0, 0, 0, 0, 9)
    GUISetState()

    MsgBox(0, 'Сообщение', 'Количество подсказок ' & _GUIToolTip_GetToolCount($hToolTip))

    While 1
        Switch GUIGetMsg()
            Case $iDel
                _GUIToolTip_DelTool($hToolTip, $hGUI, $hClose)
                MsgBox(0, 'Сообщение', 'Количество подсказок ' & _GUIToolTip_GetToolCount($hToolTip))
            Case $iClose
                Exit
            Case $GUI_EVENT_CLOSE
                Exit
        EndSwitch
    WEnd
EndFunc   ;==>Example