Функция _GUIToolTip_Create

 ↑  ←  Описание функции

_GUIToolTip_Create

Создаёт элемент ToolTip

#include <GuiToolTip.au3>
_GUIToolTip_Create($hWnd [, $iStyle = 0x00000003])

Параметры

$hWnd Дескриптор окна/элемента, который будет владельцем ToolTip
$iStyle [необязательный] Стили ToolTip:
    $TTS_ALWAYSTIP - Указывает, что элемент ToolTip появляется, когда курсор находится над объектом, даже если окно владельца ToolTip неактивно. Без этого стиля ToolTip появляется только тогда, когда окно владеющее объектом активно.
    $TTS_BALLOON - Указывает, что ToolTip имеет внешний вид как в мультфильмах, с закруглёнными углами и треугольник указывающий на пункт.
    $TTS_NOANIMATE - Disables sliding ToolTip animation on Windows 2000 system.
    $TTS_NOFADE - Disables fading ToolTip animation on Windows 2000 systems.
    $TTS_NOPREFIX - Prevents the system from stripping the ampersand character from a string. Without this style the system automatically strips ampersand characters. This allows an application to use the same string as both a menu item and as text in a ToolTip control.
    $TTS_CLOSE - Отображает иконку закрытия так, что ToolTip может быть отменён
    По умолчанию: $TTS_ALWAYSTIP, $TTS_NOPREFIX

Возвращаемое значение

Успех:Возвращает дескриптор Tooltip
Ошибка:Возвращает 0

См. также

_GUIToolTip_Destroy

Пример

#include <GUIConstantsEx.au3>
#include <GUIToolTip.au3>

Example()

Func Example()
    Local $hGUI, $hToolTip1, $hToolTip2, $iAdd, $iClear, $iClose, $iMylist, $hAdd, $hClear, $hClose, $hMylist

    $hGUI = GUICreate(StringTrimRight(@ScriptName, 4), 270, 200)

    $iAdd = GUICtrlCreateButton("Добавить", 30, 32, 75, 25)
    $hAdd = GUICtrlGetHandle(-1) ; Получает дескриптор элемента, чтобы использовать для ToolTip
    $iClear = GUICtrlCreateButton("Очистить", 30, 72, 75, 25)
    $hClear = GUICtrlGetHandle($iClear)
    $iMylist = GUICtrlCreateList("Пункт 1", 120, 32, 121, 97)
    $hMylist = GUICtrlGetHandle($iMylist)
    $iClose = GUICtrlCreateButton("Кнопка выхода", 80, 150, 110, 28)
    $hClose = GUICtrlGetHandle($iClose)

    $hToolTip1 = _GUIToolTip_Create($hGUI, $TTS_BALLOON) ; Создаёт стиль овальной подсказки
    $hToolTip2 = _GUIToolTip_Create($hGUI, $TTS_BALLOON)
    ; Устанавливает цвет для $hToolTip2
    _GUIToolTip_SetTipBkColor($hToolTip1, 0x395A00) ; Цвет фона (BGR) всплывающей подсказки
    _GUIToolTip_SetTipTextColor($hToolTip1, 0x1EBFFF) ; Цвет текста (BGR) всплывающей подсказки

    ; Выключает использование темы Windows, иначе установка цвета не работает
    ; DllCall("UxTheme.dll", "int", "SetWindowTheme", "hwnd", $hToolTip1, "wstr", 0, "wstr", 0)

    ; Устанавливает ширину ToolTip
    ; Позволяет отображать текст с переносом строки. Иначе @CRLF не будет иметь эффекта
    _GUIToolTip_SetMaxTipWidth($hToolTip1, 400)
    _GUIToolTip_SetMaxTipWidth($hToolTip2, 400)

    ; Назначает подсказку элементу
    _GUIToolTip_AddTool($hToolTip1, 0, "Добавляет пункт в список" & @CRLF & "Нужно кликнуть кнопку", $hAdd, 0, 0, 0, 0, 9)
    _GUIToolTip_AddTool($hToolTip1, 0, "Это кнопка завершения скрипта", $hClose, 0, 0, 0, 0, 9)
    _GUIToolTip_AddTool($hToolTip1, 0, "Это ListBox", $hMylist, 0, 0, 0, 0, 9)
    _GUIToolTip_AddTool($hToolTip2, 0, "Очищает список" & @CRLF & "Нужно кликнуть кнопку", $hClear, 0, 0, 0, 0, 9)
    _GUIToolTip_AddTool($hToolTip2, 0, "Подсказка" & @CRLF & "для окна GUI", $hGUI, 0, 0, 0, 0, 9)
    GUISetState()

    While 1
        Switch GUIGetMsg()
            Case $iAdd
                GUICtrlSetData($iMylist, 'Нажата кнопка "Добавить"|')
            Case $iClear
                GUICtrlSetData($iMylist, '')
            Case $iClose
                MsgBox(0, '', 'Была нажата кнопка закрытия', 2)
                Exit
            Case $GUI_EVENT_CLOSE
                Exit
        EndSwitch
    WEnd
EndFunc   ;==>Example