_GUIToolTip_Activate
Разрешает или запрещает отображение ToolTip
#include <GuiToolTip.au3>
_GUIToolTip_Activate($hWnd [, $fActivate = True])
Параметры
| $hWnd | Дескриптор ToolTip |
| $fActivate |
[необязательный] Флаг активации: True - Разрешает отображать ToolTip False - Запрещает не отображать ToolTip |
Пример
#include <GUIConstantsEx.au3>
#include <GUIToolTip.au3>
Example()
Func Example()
Local $hGUI, $hToolTip, $iAdd, $hAdd, $fActivate = True
$hGUI = GUICreate(StringTrimRight(@ScriptName, 4), 350, 200)
$iAdd = GUICtrlCreateButton("Тест", 30, 32, 180, 28)
$hAdd = GUICtrlGetHandle(-1) ; Получает дескриптор элемента, чтобы использовать для ToolTip
; Создаёт стиль овальной подсказки
$hToolTip = _GUIToolTip_Create($hGUI, $TTS_BALLOON)
; Назначает подсказку элементу
_GUIToolTip_AddTool($hToolTip, 0, "Эта кнопка вкл. или выкл. подсказки", $hAdd, 0, 0, 0, 0, 9+128)
GUISetState()
While 1
Switch GUIGetMsg()
Case $iAdd
$fActivate = Not $fActivate
_GUIToolTip_Activate($hToolTip, $fActivate)
GUICtrlSetData($iAdd, 'Показывать подсказки: ' & $fActivate)
Case $GUI_EVENT_CLOSE
Exit
EndSwitch
WEnd
EndFunc ;==>Example