Функция _GUIScrollBars_ShowScrollBar

 ↑  ←  Описание функции

_GUIScrollBars_ShowScrollBar

Показывает или скрывает полосу прокрутки

#include <GuiScrollBars.au3>
_GUIScrollBars_ShowScrollBar($hWnd, $nBar [, $fShow = True])

Параметры

$hWnd Дескриптор окна
$nBar Тип полосы прокрутки. Этот параметр может быть одним из следующих значений:
    $SB_BOTH - Показывает или скрывает стандартную горизонтальную и вертикальную полосы прокрутки окна.
    $SB_CTL - Показывает или скрывает ScrollBars. Параметр $hWnd должен быть дескриптором ScrollBars.
    $SB_HORZ - Показывает или скрывает стандартную горизонтальную полосу прокрутки окна.
    $SB_VERT - Показывает или скрывает стандартную вертикальную полосу прокрутки окна.
$fShow [необязательный] Указывает, будет ли полоса прокрутки показана или скрыта

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False

Примечания

Для выше указанных констант необходим ScrollBarConstants.au3

См. также

_GUIScrollBars_EnableScrollBar

См. также

Искать ShowScrollBar в библиотеке MSDN

Пример

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiScrollBars.au3>
#include <ScrollBarConstants.au3>

_Main()

Func _Main()
    Local $GUIMsg, $hGUI

    $hGUI = GUICreate("ScrollBar Example", 400, 400, -1, -1, BitOR($WS_MINIMIZEBOX, $WS_CAPTION, $WS_POPUP, $WS_SYSMENU, $WS_SIZEBOX))
    GUISetBkColor(0x88AABB)

    GUISetState()

    _GUIScrollBars_Init($hGUI)

    _GUIScrollBars_ShowScrollBar($hGUI, $SB_HORZ, False)
    Sleep(1000)
    _GUIScrollBars_ShowScrollBar($hGUI, $SB_HORZ)

    Sleep(1000)
    _GUIScrollBars_ShowScrollBar($hGUI, $SB_VERT, False)
    Sleep(1000)
    _GUIScrollBars_ShowScrollBar($hGUI, $SB_VERT)

    While 1
        $GUIMsg = GUIGetMsg()

        Switch $GUIMsg
            Case $GUI_EVENT_CLOSE;, $nExititem
                ExitLoop
        EndSwitch
    WEnd

    Exit
EndFunc   ;==>_Main