Функция _GUIImageList_Draw

 ↑  ←  Описание функции

_GUIImageList_Draw

Рисует изображение списка изображений в указанном контекст устройстве

#include <GuiImageList.au3>
_GUIImageList_Draw($hWnd, $iIndex, $hDC, $iX, $iY [, $iStyle=0])

Параметры

$hWnd Дескриптор ImageList
$iIndex Индекс изображения, отсчёт от 0
$hDC Дескриптор контекст устройства
$iX X-координата, где будет располагаться изображение
$iY Y-координата, где будет располагаться изображение
$iStyle [необязательный] Drawing style and overlay image:
    1 - Draws the image transparently using the mask, regardless of the background color
    2 - Draws the image, blending 25 percent with the system highlight color
    4 - Draws the image, blending 50 percent with the system highlight color
    8 - Draws the mask

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False

См. также

_GUIImageList_DrawEx

Пример

#include <GUIConstantsEx.au3>
#include <WinAPI.au3>
#include <GuiImageList.au3>

_Main()

Func _Main()
    Local $hImage, $hGUI, $hDC
    Local $Wow64
    If @AutoItX64 Then $Wow64 = "\Wow6432Node"
    Local $AutoItDir = RegRead("HKEY_LOCAL_MACHINE\SOFTWARE" & $Wow64 & "\AutoIt v3\AutoIt", "InstallDir")

    $hGUI = GUICreate("Рисует в контекст устройстве", 400, 300)
    GUISetState()

    ; Загружает изображения
    ; Создаёт список изображений
    $hImage = _GUIImageList_Create(48, 48, 5, 3)
    ; Добавляет иконки
    _GUIImageList_AddIcon($hImage, $AutoItDir & "\Icons\au3.ico")
    _GUIImageList_AddIcon($hImage, $AutoItDir & "\Icons\au3script_v9.ico")
    _GUIImageList_AddIcon($hImage, $AutoItDir & "\Icons\au3script_v10.ico")
    _GUIImageList_AddIcon($hImage, $AutoItDir & "\Icons\filetype-blank.ico")
    _GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGUI, 0xFF0000, 48, 48))
    _GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGUI, 0x00FF00, 48, 48))
    _GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGUI, 0x0000FF, 48, 48))

    ; Рисует изображение
    $hDC = _WinAPI_GetDC($hGUI)
    _GUIImageList_Draw($hImage, 0, $hDC, 4, 4)
    _GUIImageList_Draw($hImage, 1, $hDC, 64, 4)
    _GUIImageList_Draw($hImage, 2, $hDC, 124, 4)
    _GUIImageList_Draw($hImage, 3, $hDC, 184, 4)
    _GUIImageList_Draw($hImage, 4, $hDC, 4, 150)
    _GUIImageList_Draw($hImage, 5, $hDC, 64, 150)
    _GUIImageList_Draw($hImage, 6, $hDC, 124, 150)

    _WinAPI_ReleaseDC($hGUI, $hDC)

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main