Функция _GUIImageList

Функция _GUIImageList_Copy

_GUIImageList_Copy

Копирует изображения из одного индекса в другой в пределах одного списка изображений

#include <GuiImageList.au3>
_GUIImageList_Copy($hWnd, $iSource, $iDestination)

Параметры

$hWnd	Дескриптор ImageList
$iSource	Индекс изображения, который будет копироваться, отсчёт от 0
$iDestination	Индекс изображения, в который будет вставляться копия, отсчёт от 0

Возвращаемое значение

Успех:	Возвращает True
Ошибка:	Возвращает False

Примечания

Место назначения должно существовать.

См. также

_GUIImageList_Swap

Пример

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <GuiImageList.au3>

_Main()

Func _Main()
    Local $iListView, $hImage
    Local $Wow64
    If @AutoItX64 Then $Wow64 = "\Wow6432Node"
    Local $AutoItDir = RegRead("HKEY_LOCAL_MACHINE\SOFTWARE" & $Wow64 & "\AutoIt v3\AutoIt", "InstallDir")

    GUICreate("Копирует изображение", 410, 300)
    $iListView = GUICtrlCreateListView("", 2, 2, 404, 268, BitOR($LVS_SHOWSELALWAYS, $LVS_NOSORTHEADER, $LVS_REPORT))
    GUISetState()

    ; Создаёт список изображений
    $hImage = _GUIImageList_Create(16, 16, 5, 3)
; Добавляет иконки
    _GUIImageList_AddIcon($hImage, $AutoItDir & "\Icons\au3.ico")
    _GUIImageList_AddIcon($hImage, $AutoItDir & "\Icons\au3script_v9.ico")
    _GUIImageList_AddIcon($hImage, $AutoItDir & "\Icons\au3script_v10.ico")
    _GUIImageList_AddIcon($hImage, $AutoItDir & "\Icons\filetype-blank.ico")
    _GUIImageList_AddIcon($hImage, $AutoItDir & "\Icons\filetype-blank.ico")
    _GUIImageList_AddIcon($hImage, $AutoItDir & "\Icons\filetype-blank.ico")
; Копирует изображение из одного индекса в другой. Место назначения должно существовать
    _GUIImageList_Copy($hImage, 0, 3)
    _GUIImageList_Copy($hImage, 1, 4)
    _GUIImageList_Copy($hImage, 2, 5)
    _GUICtrlListView_SetImageList($iListView, $hImage, 1)

For $i = 0 To 5
_GUICtrlListView_AddItem($iListView, "Пункт " & $i, $i)
Next

    ; Добавляет колонки
    _GUICtrlListView_AddColumn($iListView, "Колонка 1", 100, 1, 0, True)
    _GUICtrlListView_AddColumn($iListView, "Колонка 2", 100, 0, 1, True)
    _GUICtrlListView_AddColumn($iListView, "Колонка 3", 100, 2, 2, True)
    _GUICtrlListView_AddColumn($iListView, "Колонка 4", 100, 0, 3)

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main