↑  ←  Описание функции

_GUICtrlTreeView_GetParentParam

Возвращает ассоциативное значение родительского пункта

#include <GuiTreeView.au3>
_GUICtrlTreeView_GetParentParam($hWnd, $hItem = 0)

Параметры

Возвращаемое значение

Пример

#include <GUIConstantsEx.au3>
#include <GuiTreeView.au3>
#include <WindowsConstants.au3>

$Debug_TV = False ; Проверяет ClassName передаваемый в функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

Example_Internal()
Example_External()

Func Example_Internal()

    Local $hItem, $hChild, $hTreeView
    Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)

    GUICreate("Параметр родительского пункта (Нативный)", 400, 300)

    $hTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
    GUISetState()

    _GUICtrlTreeView_BeginUpdate($hTreeView)
    For $x = 0 To 20
        $hItem = GUICtrlCreateTreeViewItem(StringFormat("[%02d] Пункт", $x), $hTreeView)
        For $y = 0 To 2
            $hChild = GUICtrlCreateTreeViewItem(StringFormat("[%02d] Дочерний", $y), $hItem)
        Next
    Next
    _GUICtrlTreeView_EndUpdate($hTreeView)

    _GUICtrlTreeView_SelectItem($hTreeView, $hChild)
    MsgBox(4160, "Информация", "Параметр (являющийся идентификатором) родительского пункта: " & _GUICtrlTreeView_GetParentParam($hTreeView, $hChild)) ; то же самое что ControlID

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example_Internal

Func Example_External()

    Local $GUI, $hItem, $hChild, $iParam = 1, $hTreeView
    Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)

    $GUI = GUICreate("Параметр родительского пункта (UDF)", 400, 300)

    $hTreeView = _GUICtrlTreeView_Create($GUI, 2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
    GUISetState()

    _GUICtrlTreeView_BeginUpdate($hTreeView)
    For $x = 0 To 20
        $hItem = _GUICtrlTreeView_Add($hTreeView, 0, StringFormat("[%02d] Пункт", $x))
        _GUICtrlTreeView_SetItemParam($hTreeView, $hItem, $iParam)
        $iParam += 1
        For $y = 0 To 2
            $hChild = _GUICtrlTreeView_AddChild($hTreeView, $hItem, StringFormat("[%02d] Дочерний", $y))
            _GUICtrlTreeView_SetItemParam($hTreeView, $hChild, $iParam)
            $iParam += 1
        Next
    Next
    _GUICtrlTreeView_EndUpdate($hTreeView)

    _GUICtrlTreeView_SelectItem($hTreeView, $hChild)
    MsgBox(4160, "Информация", "Параметр родительского пункта: " & _GUICtrlTreeView_GetParentParam($hTreeView, $hChild))

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example_External