Функция _GUICtrlTreeView_SetItemParam

 ↑  ←  Описание функции

_GUICtrlTreeView_SetItemParam

Устанавливает ассоциативное значение определённому пункту

#include <GuiTreeView.au3>
_GUICtrlTreeView_SetItemParam($hWnd, $hItem, $iParam)

Параметры

$hWnd Дескриптор или идентификатор элемента
$hItem Дескриптор пункта
$iParam Ассоциативное значение, связанное с пунктом

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False

Примечания

Внимание: Не используйте эту функцию с пунктами созданными нативной функцией GUICtrlCreateTreeViewItem

См. также

_GUICtrlTreeView_GetItemParam

Пример

#include <GUIConstantsEx.au3>
#include <GuiTreeView.au3>
#include <WindowsConstants.au3>

$Debug_TV = False ; Проверяет ClassName передаваемый в функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

; Предупреждение: не используйте SetItemParam для пунктов созданных функцией GUICtrlCreateTreeViewItem, так как в них значение Param содержит идентификатор пункта (ControlID).

_Main()

Func _Main()

    Local $GUI, $hItem[10], $hItemChild[30], $iYIndex = 0, $iRand, $iParam = 1, $hTreeView
    Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)

    $GUI = GUICreate("Устанавливает параметр пункта (UDF)", 400, 300)

    $hTreeView = _GUICtrlTreeView_Create($GUI, 2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
    GUISetState()

    _GUICtrlTreeView_BeginUpdate($hTreeView)
    For $x = 0 To 9
        $hItem[$x] = _GUICtrlTreeView_Add($hTreeView, 0, StringFormat("[%02d] Пункт", $x))
        _GUICtrlTreeView_SetItemParam($hTreeView, $hItem[$x], $iParam)
        $iParam += 1
        For $y = $iYIndex To $iYIndex + 2
            $hItemChild[$y] = _GUICtrlTreeView_AddChild($hTreeView, $hItem[$x], StringFormat("[%02d] Пункт", $y))
            _GUICtrlTreeView_SetItemParam($hTreeView, $hItemChild[$y], $iParam)
            $iParam += 1
        Next
        $iYIndex += 3
    Next
    _GUICtrlTreeView_EndUpdate($hTreeView)

    $iRand = Random(0, 9, 1)
    MsgBox(4160, "Информация", StringFormat("Параметр пункта для индекса %d: %s", $iRand, _GUICtrlTreeView_GetItemParam($hTreeView, $hItem[$iRand])))
    $iRand = Random(0, 29, 1)
    MsgBox(4160, "Информация", StringFormat("Параметр дочернего пункта для индекса %d: %s", $iRand, _GUICtrlTreeView_GetItemParam($hTreeView, $hItemChild[$iRand])))

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main