↑  ←  Описание функции

_GUICtrlToolbar_GetDisabledImageList

Возвращает список изображений для недоступных кнопок

#include <GuiToolBar.au3>
_GUICtrlToolbar_GetDisabledImageList($hWnd)

Параметры

Возвращаемое значение

См. также

Пример

#include <GuiToolbar.au3>
#include <GuiImageList.au3>
#include <WinAPI.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

$Debug_TB = False ; Проверяет ClassName передаваемый в функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает
Global $iMemo

_Main()

Func _Main()
    Local $hGUI, $hToolbar, $hNormal, $hDisabled, $hHot
    Local Enum $idRed = 1000, $idGreen, $idBlue

    ; Создаёт GUI
    $hGUI = GUICreate(StringTrimRight(@ScriptName, 4), 400, 300)
    GUISetBkColor(0xF0E7A6)
    $hToolbar = _GUICtrlToolbar_Create($hGUI)
    $iMemo = GUICtrlCreateEdit("", 2, 36, 396, 262, $WS_VSCROLL)
    GUICtrlSetFont($iMemo, 10, 400, 0, "Courier New")
    GUISetState()

    ; Создаёт нормальный список изображений
    $hNormal = _GUIImageList_Create(32, 24)
    _GUIImageList_Add($hNormal, _WinAPI_CreateSolidBitmap($hGUI, 0xFF0000, 32, 24))
    _GUIImageList_Add($hNormal, _WinAPI_CreateSolidBitmap($hGUI, 0x1CE31C, 32, 24))
    _GUIImageList_Add($hNormal, _WinAPI_CreateSolidBitmap($hGUI, 0x0000FF, 32, 24))
    _GUICtrlToolbar_SetImageList($hToolbar, $hNormal)

    ; Создаёт список изображений для состояния недоступный
    $hDisabled = _GUIImageList_Create(32, 24)
    _GUIImageList_Add($hDisabled, _WinAPI_CreateSolidBitmap($hGUI, 0xAAAAAA, 32, 24))
    _GUIImageList_Add($hDisabled, _WinAPI_CreateSolidBitmap($hGUI, 0xAAAAAA, 32, 24))
    _GUIImageList_Add($hDisabled, _WinAPI_CreateSolidBitmap($hGUI, 0xAAAAAA, 32, 24))
    _GUICtrlToolbar_SetDisabledImageList($hToolbar, $hDisabled)

    ; Создаёт список изображений для состояния при наведении на элемент
    $hHot = _GUIImageList_Create(32, 24)
    _GUIImageList_Add($hHot, _WinAPI_CreateSolidBitmap($hGUI, 0xFF00FF, 32, 24))
    _GUIImageList_Add($hHot, _WinAPI_CreateSolidBitmap($hGUI, 0x1CCCE3, 32, 24))
    _GUIImageList_Add($hHot, _WinAPI_CreateSolidBitmap($hGUI, 0xFF9047, 32, 24))
    _GUICtrlToolbar_SetHotImageList($hToolbar, $hHot)

    ; Добавляет кнопки
    _GUICtrlToolbar_AddButton($hToolbar, $idRed, 0)
    _GUICtrlToolbar_AddButton($hToolbar, $idGreen, 1)
    _GUICtrlToolbar_AddButton($hToolbar, $idBlue, 2)

    ; Деактивирует Синюю кнопку
    ; _GUICtrlToolbar_EnableButton($hToolbar, $idRed, False)
    ; _GUICtrlToolbar_EnableButton($hToolbar, $idGreen, False)
    _GUICtrlToolbar_EnableButton($hToolbar, $idBlue, False)

    ; Показывает дескрипторы списка изображений
    MemoWrite("Дескриптор списка недоступных .: 0x" & Hex(_GUICtrlToolbar_GetDisabledImageList($hToolbar)))
    MemoWrite("Дескриптор списка при наведении: 0x" & Hex(_GUICtrlToolbar_GetHotImageList($hToolbar)))
    MemoWrite("Дескриптор списка нормального .: 0x" & Hex(_GUICtrlToolbar_GetImageList($hToolbar)))

    MemoWrite(@CRLF & "IsPtr = " & IsPtr(_GUICtrlToolbar_GetDisabledImageList($hToolbar)) & " IsHWnd = " & IsHWnd(_GUICtrlToolbar_GetDisabledImageList($hToolbar)))

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

EndFunc   ;==>_Main

; Записывает строку в элемент для заметок
Func MemoWrite($sMessage = "")
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite