_GUICtrlSlider_SetToolTips
Назначает подсказку для Slider
#include <GuiSlider.au3>
_GUICtrlSlider_SetToolTips($hWnd, $hWndTT)
Параметры
| $hWnd | Дескриптор или идентификатор элемента |
| $hWndTT |
Дескриптор существующего элемента ToolTip |
Примечания
Когда Slider создается со стилем $TBS_TOOLTIPS, он создает элемент ToolTip по умолчанию, который появляется рядом с ползунком и отображает текущее значение Slider.См. также
_GUICtrlSlider_GetToolTipsПример
#include <GUIConstantsEx.au3>
#include <GuiSlider.au3>
#include <GuiToolTip.au3>
$Debug_S = False ; Проверяет ClassName передаваемый в функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает
_Example1()
_Example2()
Func _Example1()
Local $hGUI, $hToolTip, $hSlider
; Создаёт GUI
$hGUI = GUICreate("Устанавливает дескриптор ToolTips", 400, 296)
$hSlider = _GUICtrlSlider_Create($hGUI, 2, 2, 396, 35, BitOR($TBS_TOOLTIPS, $TBS_AUTOTICKS))
GUISetState()
; Получает дескриптор ToolTips
$hToolTip = _GUICtrlSlider_GetToolTips($hSlider)
; Устанавливает цвет для $hToolTip
_GUIToolTip_SetTipBkColor($hToolTip, 0x395A00)
_GUIToolTip_SetTipTextColor($hToolTip, 0x1EBFFF)
; Устанавливает ширину ToolTip
; Позволяет отображать текст с переносом строки. Иначе @CRLF не будет иметь эффекта
_GUIToolTip_SetMaxTipWidth($hToolTip, 400)
; Назначает подсказку элементу
_GUIToolTip_AddTool($hToolTip, 0, "Подсказка для Slider" & @CRLF & "Может быть многострочной", $hSlider, 0, 0, 0, 0, 9)
_GUICtrlSlider_SetToolTips($hSlider, $hToolTip) ; устанавливает подсказку для Slider
; Цикл выполняется, пока окно не будет закрыто
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>_Example1
Func _Example2()
Local $hGUI, $hToolTip, $hSlider
; Создаёт GUI
$hGUI = GUICreate("Устанавливает дескриптор ToolTips", 400, 296)
$hSlider = _GUICtrlSlider_Create($hGUI, 2, 2, 396, 35, BitOR($TBS_TOOLTIPS, $TBS_AUTOTICKS))
; $iSlider = GUICtrlCreateSlider(2, 2, 396, 35, BitOR($TBS_TOOLTIPS, $TBS_AUTOTICKS))
; $hSlider = GUICtrlGetHandle(-1)
GUISetState()
$hToolTip = _GUIToolTip_Create($hGUI, $TTS_BALLOON) ; Создаёт стиль овальной подсказки
; Устанавливает цвет для $hToolTip
_GUIToolTip_SetTipBkColor($hToolTip, 0x395A00)
_GUIToolTip_SetTipTextColor($hToolTip, 0x1EBFFF)
; Устанавливает ширину ToolTip
; Позволяет отображать текст с переносом строки. Иначе @CRLF не будет иметь эффекта
_GUIToolTip_SetMaxTipWidth($hToolTip, 400)
; Назначает подсказку элементу
_GUIToolTip_AddTool($hToolTip, 0, "Подсказка для Slider" & @CRLF & "Может быть многострочной", $hSlider, 0, 0, 0, 0, 9)
_GUICtrlSlider_SetToolTips($hSlider, $hToolTip) ; устанавливает подсказку для Slider
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>_Example2