_GUICtrlRichEdit_SetPasswordChar
Вместо символов набранных пользователем отображает символы указанные в функции
#include <GuiRichEdit.au3>
_GUICtrlRichEdit_SetPasswordChar($hWnd [, $cDisplayChar = "0"])
Параметры
| $hWnd | Дескриптор элемента |
| $cDisplayChar |
[необязательный] Символ, который будет отображаться вместо символов, введенных пользователем. Специальное значение: "" - (пустая строка) отображаются символы введённые пользователем |
Возвращаемое значение
| Succcess: | Возвращает True |
| Ошибка: | Возвращает False и устанавливает @error |
| @error: | 101 - $HWnd не является дескриптором |
| 102 - $cDisplayChar не является символом |
См. также
_GUICtrlRichEdit_GetPasswordCharСм. также
Искать EM_SETPASSWORDCHAR в библиотеке MSDNПример
#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
Global $lblMsg, $hRichEdit
Main()
Func Main()
Local $hGui, $btnNext, $iStep = 0
$hGui = GUICreate(StringTrimRight(@ScriptName, 4), 420, 350, -1, -1)
$hRichEdit = _GUICtrlRichEdit_Create($hGui, 'Это тест.', 10, 10, 400, 220, _
BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
$lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
$btnNext = GUICtrlCreateButton("Далее", 270, 310, 60, 30)
GUISetState()
Report("Начальное состояние после создания элемента")
While 1
Switch GUIGetMsg()
Case $GUI_EVENT_CLOSE
_GUICtrlRichEdit_Destroy($hRichEdit)
GUIDelete()
Exit
Case $btnNext
$iStep += 1
Switch $iStep
Case 1
_GUICtrlRichEdit_SetPasswordChar($hRichEdit, "*")
Report("Символ пароля изменён. Введите некоторый текст")
Case 2
_GUICtrlRichEdit_SetPasswordChar($hRichEdit, "")
Report("Восстановление предыдущего")
GUICtrlSetState($btnNext, $GUI_DISABLE)
EndSwitch
EndSwitch
WEnd
EndFunc ;==>Main
Func Report($sMsg)
Local $ch
$ch = _GUICtrlRichEdit_GetPasswordChar($hRichEdit)
If $ch = "" Then
$sMsg &= @CR & "Символы отображаются как есть"
Else
$sMsg = $sMsg & @CR & "Введенные символы отображаются в виде " & $ch
EndIf
GUICtrlSetData($lblMsg, $sMsg)
ControlFocus($hRichEdit, "", "")
EndFunc ;==>Report