Функция _GUICtrlRichEdit_GetRECT

 ↑  ←  Описание функции

_GUICtrlRichEdit_GetRECT

Возвращает прямоугольник форматирования

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetRECT($hWnd)

Параметры

$hWnd Дескриптор элемента

Возвращаемое значение

Успех:Возвращает массив, состоящий из координат x и y - [<left>,<top>,<right>,<bottom>]
Ошибка:устанавливает @error
@error:101 - $HWnd не является дескриптором

Примечания

Прямоугольник форматирования это область, в которой рисуется текст, часть которого может быть не видна.

Все возвращаемые значения связанные с элементом измеряются в диалоговых единицах

Из MSDN: возвращаемые этой функцией значения могут быть не точно такими же, которые установлены функцией _GUICtrlRichEdit_SetRECT()

См. также

_GUICtrlRichEdit_SetRECT

См. также

Искать EM_GETRECT в библиотеке MSDN

Пример

#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $lblMsg, $hRichEdit

Main()

Func Main()
    Local $hGui, $btnNext, $iStep = 0
    $hGui = GUICreate(StringTrimRight(@ScriptName, 4), 420, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, 'Это тест.', 10, 10, 400, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $lblMsg = GUICtrlCreateLabel("", 10, 235, 260, 110)
    $btnNext = GUICtrlCreateButton("Далее", 270, 310, 60, 30)
    GUISetState()

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                _GUICtrlRichEdit_Destroy($hRichEdit)
                GUIDelete()
                Exit
            Case $btnNext
                $iStep += 1
                Switch $iStep
                    Case 1
                        Report("1. Текущие установки ")
                    Case 2
                        _GUICtrlRichEdit_SetRECT($hRichEdit, 10, 10, 100, 100)
                        Report("2. Изменение ")
                    Case 3
                        _GUICtrlRichEdit_SetRECT($hRichEdit)
                        Report("3. Восстановление по умолчанию")
                        GUICtrlSetState($btnNext, $GUI_DISABLE)
                EndSwitch
        EndSwitch
    WEnd
EndFunc   ;==>Main

Func Report($sMsg)
    Local $aRect =  _GUICtrlRichEdit_GetRECT($hRichEdit)
    $sMsg &=  @CR & @CR & _
        "Левая   =" & $aRect[0] & @CR & _
        "Верхняя=" & $aRect[1] & @CR & _
        "Правая =" & $aRect[2] & @CR & _
        "Нижняя=" & $aRect[3]
    GUICtrlSetData($lblMsg, $sMsg)
    ControlFocus($hRichEdit, "", "")
EndFunc   ;==>Report