Функция _GUICtrlRichEdit_GetLineCount

 ↑  ←  Описание функции

_GUICtrlRichEdit_GetLineCount

Возвращает количество строк в многострочном элементе Rich Edit

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetLineCount($hWnd)

Параметры

$hWnd Дескриптор элемента

Возвращаемое значение

Успех:Возвращает общее количество строк
Ошибка:Возвращает 0 и устанавливает @error
@error:101 - $HWnd не является дескриптором

Примечания

Элемент, не содержащий текста имеет одну строку

Строки не отображающиеся в данный момент учитываются при подсчёте

Если используется стиль с переносом строк, то количество строк может измениться, при изменении размеров элемента Rich Edit.

См. также

Искать EM_GETLINECOUNT в библиотеке MSDN

Пример

#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $lblMsg, $hRichEdit

Main()

Func Main()
    Local $hGui
    $hGui = GUICreate(StringTrimRight(@ScriptName, 4), 420, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, 'Это тест.', 10, 10, 400, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    GUISetState()

    For $i = 2 To 10
        _GUICtrlRichEdit_AppendText($hRichEdit, @CR & "строка " & $i)
    Next

    Report("Элемент содержит " & _GUICtrlRichEdit_GetLineCount($hRichEdit) & " строк")

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                _GUICtrlRichEdit_Destroy($hRichEdit)
                GUIDelete()
                Exit
        EndSwitch
    WEnd
EndFunc   ;==>Main

Func Report($sMsg)
    GUICtrlSetData($lblMsg, $sMsg)
EndFunc   ;==>Report