_GUICtrlRichEdit_GetCharPosFromXY
Возвращает межсимвольную позицию ближайшую к указанным координатам относительно клиентской области
#include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetCharPosFromXY($hWnd, $iX, $iY)
Параметры
| $hWnd | Дескриптор элемента |
| $iX |
Горизонтальная координата относительно левой стороны элемента |
| $iY |
Вертикальная координата относительно верхней стороны элемента |
Возвращаемое значение
| Успех: | Возвращает индекс межсимвольной позиции ближайшую к указанным координатам, отсчёт от 1 |
| (индекс крайнего символа в элементе, если указанная точка находится за пределами текста) | |
| Ошибка: | Возвращает 0 и устанавливает @error |
| @error: | 101 - $HWnd не является дескриптором |
| 102 - $iX не является числом | |
| 103 - $iY не является числом | |
| -1 - ($iX,$iY) за пределами клиентской области |
См. также
_GUICtrlRichEdit_GetXYFromCharPosСм. также
Искать EM_CHARFROMPOS в библиотеке MSDNПример
#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
Main()
Func Main()
Local $hGui, $ai, $btnNext, $iStep = 0, $lblMsg, $hRichEdit
$hGui = GUICreate(StringTrimRight(@ScriptName, 4), 420, 350, -1, -1)
$hRichEdit = _GUICtrlRichEdit_Create($hGui, 'Это тест.', 10, 10, 400, 220, _
BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
$lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
$btnNext = GUICtrlCreateButton("Далее", 270, 310, 60, 30)
GUISetState()
_GUICtrlRichEdit_AppendText($hRichEdit, @CR & 'Добавленный текст.')
While 1
Switch GUIGetMsg()
Case $GUI_EVENT_CLOSE
_GUICtrlRichEdit_Destroy($hRichEdit)
GUIDelete()
Exit
Case $btnNext
$iStep += 1
Switch $iStep
Case 1
$ai = _GUICtrlRichEdit_GetXYFromCharPos($hRichEdit, 20)
GUICtrlSetData($lblMsg, "1. Координаты межсимвольной позиции 20: (" & $ai[0] & "," & $ai[1] & ")")
_GUICtrlRichEdit_GotoCharPos($hRichEdit, 20)
Case 2
GUICtrlSetData($lblMsg, "2.Межсимвольная позиция ближайшая к координатам (" & $ai[0] & "," & $ai[1] & ") равна " & _
_GUICtrlRichEdit_GetCharPosFromXY($hRichEdit, $ai[0], $ai[1]))
_GUICtrlRichEdit_GotoCharPos($hRichEdit, 20)
GUICtrlSetState($btnNext, $GUI_DISABLE)
EndSwitch
EndSwitch
WEnd
EndFunc