Функция _GUICtrlMenu_TrackPopupMenu

         Описание функции

_GUICtrlMenu_TrackPopupMenu

Отображает контекстное меню в указанных координатах

#include <GuiMenu.au3>
_GUICtrlMenu_TrackPopupMenu($hMenu, $hWnd [, $iX = -1 [, $iY = -1 [, $iAlignX = 1 [, $iAlignY = 1 [, $iNotify = 0 [, $iButtons = 0]]]]]])

Параметры

$hMenu Дескриптор отображаемого контекстного меню
$hWnd Дескриптор окна, владеющего контекстным меню
$iX [необязательный] X-координата отображения контекстного меню в экранных координатах. Если -1, то используется текущая X-координата мыши.
$iY [необязательный] Y-координата отображения контекстного меню в экранных координатах. Если -1, то используется текущая Y-координата мыши.
$iAlignX [необязательный] Указывает, как позиционируется меню по горизонтали:
    0 - Меню позиционируется так, что его центр по горизонтали совмещается с $iX
    1 - Меню позиционируется так, что его левая сторона совмещается с $iX
    2 - Меню позиционируется так, что его правая сторона совмещается с $iX
$iAlignY [необязательный] Указывает, как позиционируется меню по вертикали:
    0 - Меню позиционируется так, что его нижняя сторона совмещается с $iY
    1 - Меню позиционируется так, что его верхняя сторона совмещается с $iY
    2 - Меню позиционируется так, что его центр по вертикали совмещается с $iY
$iNotify [необязательный] Используется, чтобы определить выбор при отсутствии (?) родительского окна:
    1 - Не высылать уведомительные сообщения
    2 - Возвращает идентификатор пункта меню, выбранный пользователем
$iButtons [необязательный] Mouse button the shortcut menu tracks:
    0 - Пользователь может выбрать пункт только левой кнопкой мыши
    1 - Пользователь может выбрать пункт обоими кнопками мыши, левой и правой

Возвращаемое значение

Успех:Если $iNotify равен 2, то возвращается идентификатор пункта меню, выбранный пользователем. Если пользователь отменяет меню не сделав выбор пункта или произошла ошибка, то возвращается 0. Если $iNotify не равно 2, то возвращается 1.
Ошибка:Возвращает 0

См. также

Искать TrackPopupMenu в библиотеке MSDN

Пример

#include <GuiMenu.au3>
#include <GUIConstantsEx.au3>
#include <WinAPI.au3>
#include <WindowsConstants.au3>

Global Enum $idOpen = 1000, $idSave, $idInfo

_Main()

Func _Main()
    ; Создаёт GUI
    GUICreate("Menu", 400, 300)
    GUISetState()

    ; Регистрация обработчика сообщений
    GUIRegisterMsg($WM_COMMAND, "WM_COMMAND")
    GUIRegisterMsg($WM_CONTEXTMENU, "WM_CONTEXTMENU")

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

EndFunc   ;==>_Main

; Обработчик сообщений WM_COMMAND
Func WM_COMMAND($hWnd, $iMsg, $iwParam, $ilParam)
    #forceref $hWnd, $iMsg, $ilParam
    Switch $iwParam
        Case $idOpen
            _WinAPI_ShowMsg ("Открыть")
        Case $idSave
            _WinAPI_ShowMsg ("Сохранить")
        Case $idInfo
            _WinAPI_ShowMsg ("Информация")
    EndSwitch
EndFunc   ;==>WM_COMMAND

; Обработчик сообщений WM_CONTEXTMENU
Func WM_CONTEXTMENU($hWnd, $iMsg, $iwParam, $ilParam)
    #forceref $hWnd, $iMsg, $ilParam
    Local $hMenu

    $hMenu = _GUICtrlMenu_CreatePopup ()
    _GUICtrlMenu_InsertMenuItem ($hMenu, 0, "Открыть", $idOpen)
    _GUICtrlMenu_InsertMenuItem ($hMenu, 1, "Сохранить", $idSave)
    _GUICtrlMenu_InsertMenuItem ($hMenu, 3, "", 0)
    _GUICtrlMenu_InsertMenuItem ($hMenu, 3, "Информация", $idInfo)
    _GUICtrlMenu_TrackPopupMenu ($hMenu, $iwParam)
    _GUICtrlMenu_DestroyMenu ($hMenu)
    Return True
EndFunc   ;==>WM_CONTEXTMENU