Функция _GUICtrlMenu

Функция _GUICtrlMenu_InsertMenuItem

_GUICtrlMenu_InsertMenuItem

Вставляет новый пункт в указанную позицию в меню

#include <GuiMenu.au3>
_GUICtrlMenu_InsertMenuItem($hMenu, $iIndex, $sText [, $iCmdID = 0 [, $hSubMenu = 0]])

Параметры

$hMenu	Дескриптор меню
$iIndex	Позиция пункта меню, перед которым вставляется новый пункт, отсчёт от 0
$sText	Текст пункта меню. Если пустая строка, то вставляется разделитель.
$iCmdID	[необязательный] Идентификатор команды назначаемый пункту
$hSubMenu	[необязательный] Дескриптор подменю связанный с этим пунктом меню

Возвращаемое значение

Успех:	Возвращает True
Ошибка:	Возвращает False

См. также

_GUICtrlMenu_InsertMenuItemEx, _GUICtrlMenu_AddMenuItem, _GUICtrlMenu_AppendMenu

См. также

Искать InsertMenuItem в библиотеке MSDN

Пример

#include <GuiMenu.au3>
#include <GUIConstantsEx.au3>

_Main()

Func _Main()
Local $hGUI, $hFile, $hEdit, $hHelp, $hMain
Local Enum $idNew = 1000, $idOpen, $idSave, $idExit, $idCut, $idCopy, $idPaste, $idAbout

; Создаёт GUI
$hGUI = GUICreate("Вставляет пункт", 400, 300)

; Создаёт меню "Файл"
$hFile = _GUICtrlMenu_CreateMenu ()
_GUICtrlMenu_InsertMenuItem ($hFile, 0, 'Новый', $idNew)
_GUICtrlMenu_InsertMenuItem ($hFile, 1, 'Открыть', $idOpen)
_GUICtrlMenu_InsertMenuItem ($hFile, 2, 'Сохранить', $idSave)
_GUICtrlMenu_InsertMenuItem ($hFile, 3, "", 0)
_GUICtrlMenu_InsertMenuItem ($hFile, 4, 'Выход', $idExit)

; Создаёт меню "Правка"
$hEdit = _GUICtrlMenu_CreateMenu ()
_GUICtrlMenu_InsertMenuItem ($hEdit, 0, 'Вырезать', $idCut)
_GUICtrlMenu_InsertMenuItem ($hEdit, 1, 'Копировать', $idCopy)
_GUICtrlMenu_InsertMenuItem ($hEdit, 2, 'Вставить', $idPaste)

; Создаёт меню "Справка"
$hHelp = _GUICtrlMenu_CreateMenu ()
_GUICtrlMenu_InsertMenuItem ($hHelp, 0, 'О программе', $idAbout)

; Создаёт главное меню
$hMain = _GUICtrlMenu_CreateMenu ()
_GUICtrlMenu_InsertMenuItem ($hMain, 0, 'Файл', 0, $hFile)
_GUICtrlMenu_InsertMenuItem ($hMain, 1, 'Правка', 0, $hEdit)
_GUICtrlMenu_InsertMenuItem ($hMain, 2, 'Справка', 0, $hHelp)

; Устанавливает главное меню окна
_GUICtrlMenu_SetMenu ($hGUI, $hMain)
GUISetState()

; Цикл выполняется, пока окно не будет закрыто
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc ;==>_Main