Функция _GUICtrlMenu

Функция _GUICtrlMenu_AddMenuItem

_GUICtrlMenu_AddMenuItem

Добавляет новый пункт меню в конец меню

#include <GuiMenu.au3>
_GUICtrlMenu_AddMenuItem($hMenu, $sText [, $iCmdID = 0 [, $hSubMenu = 0]])

Параметры

$hMenu	Дескриптор меню
$sText	Текст пункта меню. Если пустая строка, то добавляется разделитель.
$iCmdID	[необязательный] Идентификатор команды назначаемый пункту
$hSubMenu	[необязательный] Дескриптор подменю связанный с этим пунктом меню

Возвращаемое значение

Успех:	Возвращает индекс пункта меню, отсчёт от 0
Ошибка:	Возвращает -1

См. также

_GUICtrlMenu_InsertMenuItem

Пример

#include <GuiMenu.au3>
#include <GUIConstantsEx.au3>

_Main()

Func _Main()
Local $hGUI, $hFile, $hEdit, $hHelp, $hMain
Local Enum $idNew = 1000, $idOpen, $idSave, $idExit, $idCut, $idCopy, $idPaste, $idAbout

; Создаёт GUI
$hGUI = GUICreate("Добавляет пункт", 400, 300)

; Создаёт меню "Файл"
$hFile = _GUICtrlMenu_CreateMenu ()
_GUICtrlMenu_AddMenuItem ($hFile, "Новый", $idNew)
_GUICtrlMenu_AddMenuItem ($hFile, 'Открыть', $idOpen)
_GUICtrlMenu_AddMenuItem ($hFile, 'Сохранить', $idSave)
_GUICtrlMenu_AddMenuItem ($hFile, "", 0)
_GUICtrlMenu_AddMenuItem ($hFile, 'Выход', $idExit)

; Создаёт меню "Правка"
$hEdit = _GUICtrlMenu_CreateMenu ()
_GUICtrlMenu_AddMenuItem ($hEdit, 'Вырезать', $idCut)
_GUICtrlMenu_AddMenuItem ($hEdit, 'Копировать', $idCopy)
_GUICtrlMenu_AddMenuItem ($hEdit, 'Вставить', $idPaste)

; Создаёт меню "Справка"
$hHelp = _GUICtrlMenu_CreateMenu ()
_GUICtrlMenu_AddMenuItem ($hHelp, 'О программе', $idAbout)

; Создаёт главное меню
$hMain = _GUICtrlMenu_CreateMenu ()
_GUICtrlMenu_AddMenuItem ($hMain, 'Файл', 0, $hFile)
_GUICtrlMenu_AddMenuItem ($hMain, 'Правка', 0, $hEdit)
_GUICtrlMenu_AddMenuItem ($hMain, 'Справка', 0, $hHelp)

; Устанавливает главное меню окна
_GUICtrlMenu_SetMenu ($hGUI, $hMain)
GUISetState()

; Цикл выполняется, пока окно не будет закрыто
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc ;==>_Main