Функция _GUICtrlMenu_CheckMenuItem

         Описание функции

_GUICtrlMenu_CheckMenuItem

Устанавливает или снимает галочку с указанного пункта меню

#include <GuiMenu.au3>
_GUICtrlMenu_CheckMenuItem($hMenu, $iItem [, $fCheck = True [, $fByPos = True]])

Параметры

$hMenu Дескриптор меню
$iItem Идентификатор или позиция пункта меню
$fCheck [необязательный] Устанавливает состояние
    True - Устанавливает галочку
    False - Снимает галочку
$fByPos [необязательный] Флаг для идентификации меню:
    True - $iItem является позицией пункта, отсчёт от 0
    False - $iItem является идентификатором пункта

Возвращаемое значение

Успех:Возвращает предыдущее состояние пункта меню ($MF_CHECKED или $MF_UNCHECKED)
Ошибка:Возвращает -1

Примечания

Пункт главного меню не может иметь галочки. Параметр $iItem может быть пунктом раскрывающегося подменю или пунктом-командой. Для пункта, который раскрывает подменю параметр $Item должен указывать позицию пункта. Для пункта-команды параметр $Item может указывать идентификатор или позицию.

См. также

_GUICtrlMenu_CheckRadioItem

См. также

Искать CheckMenuItem в библиотеке MSDN

Пример

#include <GuiMenu.au3>
#include <GUIConstantsEx.au3>

_Main()

Func _Main()
    Local $hGUI, $hFile, $hEdit, $hHelp, $hMain
    Local Enum $idNew = 1000, $idOpen, $idSave, $idExit, $idCut, $idCopy, $idPaste, $idAbout

    ; Создаёт GUI
    $hGUI = GUICreate("Устанавливает / снимает галочку ", 400, 300)

    ; Создаёт меню "Файл"
    $hFile = _GUICtrlMenu_CreateMenu ()
    _GUICtrlMenu_InsertMenuItem ($hFile, 0, 'Новый', $idNew)
    _GUICtrlMenu_InsertMenuItem ($hFile, 1, 'Открыть', $idOpen)
    _GUICtrlMenu_InsertMenuItem ($hFile, 2, 'Сохранить', $idSave)
    _GUICtrlMenu_InsertMenuItem ($hFile, 3, "", 0)
    _GUICtrlMenu_InsertMenuItem ($hFile, 4, 'Выход', $idExit)

    ; Создаёт меню "Правка"
    $hEdit = _GUICtrlMenu_CreateMenu ()
    _GUICtrlMenu_InsertMenuItem ($hEdit, 0, 'Вырезать', $idCut)
    _GUICtrlMenu_InsertMenuItem ($hEdit, 1, 'Копировать', $idCopy)
    _GUICtrlMenu_InsertMenuItem ($hEdit, 2, 'Вставить', $idPaste)

    ; Создаёт меню "Справка"
    $hHelp = _GUICtrlMenu_CreateMenu ()
    _GUICtrlMenu_InsertMenuItem ($hHelp, 0, 'О программе', $idAbout)

    ; Создаёт главное меню
    $hMain = _GUICtrlMenu_CreateMenu ()
    _GUICtrlMenu_InsertMenuItem ($hMain, 0, 'Файл', 0, $hFile)
    _GUICtrlMenu_InsertMenuItem ($hMain, 1, 'Правка', 0, $hEdit)
    _GUICtrlMenu_InsertMenuItem ($hMain, 2, 'Справка', 0, $hHelp)

    ; Устанавливает главное меню окна
    _GUICtrlMenu_SetMenu ($hGUI, $hMain)
    GUISetState()

    ; Устанавливает галочку на пункте меню "Сохранить"
    _GUICtrlMenu_CheckMenuItem ($hFile, 2)

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>_Main