Функция _GUICtrlListView_SetItemEx

         Описание функции

_GUICtrlListView_SetItemEx

Устанавливает некоторые или все атрибуты пункта

#include <GuiListView.au3>
_GUICtrlListView_SetItemEx($hWnd, ByRef $tItem)

Параметры

$hWnd Дескриптор или идентификатор элемента
$tItem Структура $tagLVITEM

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False

Примечания

Чтобы установить атрибуты пункта установите элемент "Item" в структуре $tagLVITEM в индекс пункта, и установите элемент "SubItem" в ноль. Для пункта, вы можете установить значения элементов "State" (состояние), "Text" (текст), "Image" (изображение), и "Param" (связанное с пунктом значение), которые являются элементами структуры $tagLVITEM.

Чтобы установить текст подпункта, установите значения элементов "Item" и "SubItem" в указанный индекс подпункта, и используйте элемент "Text", чтобы указать текст. Вы не можете установить элементы "State" или "Param" для подпункта потому что подпункты не имеют этих атрибутов.

См. также

_GUICtrlListView_SetItem, $tagLVITEM

Пример

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>

$Debug_LV = False ; Проверяет ClassName передаваемый в ListView функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()
    Local $tText, $tItem, $hListView

    GUICreate("Устанавливает атрибуты пункта (Ex)", 400, 300)
    $hListView = GUICtrlCreateListView("", 2, 2, 394, 268)
    GUISetState()

    ; Добавляет колонки
    _GUICtrlListView_AddColumn($hListView, "Пункты", 140)

    ; Добавляет пункты
    GUICtrlCreateListViewItem("Пункт 1", $hListView)
    GUICtrlCreateListViewItem("Пункт 2", $hListView)
    GUICtrlCreateListViewItem("Пункт 3", $hListView)

    ; Изменяет 2-ой пункт
    MsgBox(4160, "Информация", "Изменяет 2-ой пункт")
    $tText = DllStructCreate("wchar Text[14]") ; на 1 больше чем кол. символов
    $tItem = DllStructCreate($tagLVITEM)
    DllStructSetData($tText, "Text", "Новый пункт 2")
    DllStructSetData($tItem, "Mask", $LVIF_TEXT)
    DllStructSetData($tItem, "Item", 1)
    DllStructSetData($tItem, "Text", DllStructGetPtr($tText))
    _GUICtrlListView_SetItemEx($hListView, $tItem)

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main