Функция _GUICtrlListView_SetItem

         Описание функции

_GUICtrlListView_SetItem

Устанавливает некоторые или все атрибуты пункта

#include <GuiListView.au3>
_GUICtrlListView_SetItem($hWnd, $sText [, $iIndex = 0 [, $iSubItem = 0 [, $iImage = -1 [, $iParam = -1 [, $iIndent = -1]]]]])

Параметры

$hWnd Дескриптор или идентификатор элемента
$sText Текст пункта. См. примечания
$iIndex [необязательный] Индекс пункта, отсчёт от 0
$iSubItem [необязательный] Индекс подпункта или 0, если это относится к пункту, отсчёт от 1
$iImage [необязательный] Индекс иконки в списке изображений, отсчёт от 0
$iParam [необязательный] Дополнительные параметры пункта
$iIndent [необязательный] Отступ определяемый количеством размеров изображений. Один отступ равен ширине изображения.

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False

Примечания

Если необходимо уведомления обратного вызова (callback) укажите $sText = -1 (LPSTR_TEXTCALLBACK).

См. также

_GUICtrlListView_GetItem, _GUICtrlListView_SetItemEx

Пример

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>

$Debug_LV = False ; Проверяет ClassName передаваемый в ListView функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()
    Local $hListView

    GUICreate("Устанавливает атрибуты пункта", 400, 300)
    $hListView = GUICtrlCreateListView("", 2, 2, 394, 268)
    GUISetState()

    ; Добавляет колонки
    _GUICtrlListView_AddColumn($hListView, "Пункты", 120)

    ; Добавляет пункты
    GUICtrlCreateListViewItem("Пункт 1", $hListView)
    GUICtrlCreateListViewItem("Пункт 2", $hListView)
    GUICtrlCreateListViewItem("Пункт 3", $hListView)

    ; Изменяет 2-ой пункт
    MsgBox(4160, "Информация", "Изменяет 2-ой пункт")
    _GUICtrlListView_SetItem($hListView, "Новый пункт 2", 1)

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main