Функция _GUICtrlListView_SetItemChecked

         Описание функции

_GUICtrlListView_SetItemChecked

Устанавливает состояние Checkbox (галочки в квадрате)

#include <GuiListView.au3>
_GUICtrlListView_SetItemChecked($hWnd, $iIndex [, $fCheck = True])

Параметры

$hWnd Дескриптор или идентификатор элемента
$iIndex Индекс пункта, -1 устанавливает состояние для всех пунктов ListView
$fCheck [необязательный] Значение, устанавливающее состояние:
    True - Устанавливает галочку
    False - Снимает галочку

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False

Примечания

Используется только для элементов имеющих стиль $LVS_EX_CHECKBOXES

См. также

_GUICtrlListView_GetItemChecked

Пример

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>

$Debug_LV = False ; Проверяет ClassName передаваемый в ListView функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()
    Local $exStyles = BitOR($LVS_EX_FULLROWSELECT, $LVS_EX_CHECKBOXES), $hListView

    GUICreate("Устанав. / снимает галочку пункта", 400, 300)
    $hListView = GUICtrlCreateListView("", 2, 2, 394, 268)
    _GUICtrlListView_SetExtendedListViewStyle($hListView, $exStyles)
    GUISetState()

    ; Добавляет колонки
    _GUICtrlListView_AddColumn($hListView, "Колонка 1", 120)
    _GUICtrlListView_AddColumn($hListView, "Колонка 2", 100)
    _GUICtrlListView_AddColumn($hListView, "Колонка 3", 100)

    ; Добавляет пункты
    _GUICtrlListView_AddItem($hListView, "Стр 1: Кол 1", 0)
    _GUICtrlListView_AddSubItem($hListView, 0, "Стр 1: Кол 2", 1)
    _GUICtrlListView_AddSubItem($hListView, 0, "Стр 1: Кол 3", 2)
    _GUICtrlListView_AddItem($hListView, "Стр 2: Кол 1", 1)
    _GUICtrlListView_AddSubItem($hListView, 1, "Стр 2: Кол 2", 1)
    _GUICtrlListView_AddItem($hListView, "Стр 3: Кол 1", 2)

    ; Ставит галочку на 2-ом  пункте
    _GUICtrlListView_SetItemChecked($hListView, 1)
    MsgBox(4160, "Информация", "Галочка на 2-м пункте: " & _GUICtrlListView_GetItemChecked($hListView, 1))

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main