Функция _GUICtrlListView_GetSelectedIndices

         Описание функции

_GUICtrlListView_GetSelectedIndices

Возвращает индексы выделенных пунктов

#include <GuiListView.au3>
_GUICtrlListView_GetSelectedIndices($hWnd, $fArray = False)

Параметры

$hWnd Дескриптор или идентификатор элемента
$fArray Возвращает строку или массив
    True - Возвращает массив
    False - Возвращает строку с разделителем "|"

Возвращаемое значение

Успех:Возвращает индексы выделенных пунктов, строку или массив:
Массив - следующего формата
[0] - Количество пунктов в массиве (n)
[1] - Первый индекс пункта
[2] - Второй индекс пункта
[n] - Последний индекс пункта
Строка - следующего формата
"0|1|2|n"
Ошибка:строку или массив
Массив - следующего формата
[0] - Количество пунктов в массиве (0)
Строка - Пустая ("")

Пример

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>

$Debug_LV = False ; Проверяет ClassName передаваемый в ListView функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()
    Local $hListView

    GUICreate("Получает индексы выделенных", 400, 300)
    $hListView = GUICtrlCreateListView("", 2, 2, 394, 268, BitOR($LVS_SHOWSELALWAYS, $LVS_REPORT))
    GUISetState()

    ; Добавляет колонки
    _GUICtrlListView_AddColumn($hListView, "Колонка 1", 100)

    ; Добавляет пункты
    _GUICtrlListView_AddItem($hListView, "Пункт 1")
    _GUICtrlListView_AddItem($hListView, "Пункт 2")
    _GUICtrlListView_AddItem($hListView, "Пункт 3")

    ; Выделяет несколько пунктов
    _GUICtrlListView_SetItemSelected($hListView, 1)
    _GUICtrlListView_SetItemSelected($hListView, 2)
    MsgBox(4160, "Информация", "Индексы выделенных: " & _GUICtrlListView_GetSelectedIndices($hListView))

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main