Функция _GUICtrlListView_GetNextItem

         Описание функции

_GUICtrlListView_GetNextItem

Поиск пункта, который имеет указанные свойства

#include <GuiListView.au3>
_GUICtrlListView_GetNextItem($hWnd [, $iStart = -1 [, $iSearch = 0 [, $iState = 8]]])

Параметры

$hWnd Дескриптор или идентификатор элемента
$iStart [необязательный] Индекс пункта, от которого начинать поиск, или -1, для поиска первого пункта, который соответствует указанному флагу. Указанный пункт исключается из поиска.
$iSearch [необязательный] Направление поиска относительно указанного индекса:
    0 - Поиск последующего пункта по индексу
    1 - Поиск пункта выше от указанного пункта
    2 - Поиск пункта ниже от указанного пункта
    3 - Поиск пункта слева от указанного пункта
    4 - Поиск пункта справа от указанного пункта
$iState [необязательный] Состояние искомого пункта. Может быть комбинацией следующих значений:
    1 - Пункт вырезан
    2 - Пункт выделен
    4 - Пункт с фокусом
    8 - Пункт выбран

Возвращаемое значение

Успех:Возвращает индекс следующего пункта
Ошибка:Возвращает -1

Пример

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>

$Debug_LV = False ; Проверяет ClassName передаваемый в ListView функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()
    Local $hListView

    GUICreate("ListView Получает следующий пункт", 400, 300)
    $hListView = GUICtrlCreateListView("", 2, 2, 394, 268)
    GUISetState()

    ; Добавляет колонки
    _GUICtrlListView_AddColumn($hListView, "Пункты", 100)

    ; Добавляет пункты
    _GUICtrlListView_AddItem($hListView, "Пункт 1")
    _GUICtrlListView_AddItem($hListView, "Пункт 2")
    _GUICtrlListView_AddItem($hListView, "Пункт 3")

    ; Выделяет 2-ой пункт
    _GUICtrlListView_SetItemSelected($hListView, 1)

    ; Найти выделенный пункт
    MsgBox(4160, "Информация", "Выделенный пункт: " & _GUICtrlListView_GetNextItem($hListView))

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main