Функция _GUICtrlListView_FindInText

         Описание функции

_GUICtrlListView_FindInText

Поиск пунктов, которые содержат текст в любом месте текста пункта

#include <GuiListView.au3>
_GUICtrlListView_FindInText($hWnd, $sText [, $iStart = -1 [, $fWrapOK = True [, $fReverse = False]]])

Параметры

$hWnd Дескриптор или идентификатор элемента
$sText Искомый текст
$iStart [необязательный] Индекс, от которого начинать поиск или -1, чтобы искать с самого начала. Указанный элемент исключается из поиска.
$fWrapOK [необязательный] Если True, то поиск продолжится от первого пункта, если ни одного соответствия не найдено
$fReverse [необязательный] Если True, то поиск начинается от $iStart - 1 к нулю. Если $fWrapOK = True, то поиск продолжится

Возвращаемое значение

Успех:Возвращает индекс пункта
Ошибка:Возвращает -1

Примечания

Поиск без учёта регистра. В отличие от _GUICtrlListView_FindText, эта функция будет искать текст во всех подпунктах.

См. также

_GUICtrlListView_FindText

Пример

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>

$Debug_LV = False ; Проверяет ClassName передаваемый в ListView функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()
    Local $iI, $hListView

    GUICreate("ListView - Поиск в строке", 400, 300)
    $hListView = GUICtrlCreateListView("", 2, 2, 394, 268)
    GUISetState()

    ; Добавляет колонки
    _GUICtrlListView_InsertColumn($hListView, 0, "Пункты", 140)

    ; Добавляет пункты
    _GUICtrlListView_BeginUpdate($hListView)
    For $iI = 1 To 49
        _GUICtrlListView_AddItem($hListView, "Пункт " & $iI)
    Next
    _GUICtrlListView_AddItem($hListView, "Пункт назначения")
    For $iI = 51 To 100
        _GUICtrlListView_AddItem($hListView, "Пункт " & $iI)
    Next
    _GUICtrlListView_EndUpdate($hListView)

    ; Поиск пункта назначения
    $iI = _GUICtrlListView_FindInText($hListView, "нАзНаЧеНиЯ")
    MsgBox(4160, "Информация", "Индекс пункта назначения: " & $iI)
    _GUICtrlListView_EnsureVisible($hListView, $iI)

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main