Функция _GUICtrlListBox_SetCaretIndex

         Описание функции

_GUICtrlListBox_SetCaretIndex

Устанавливает прямоугольник фокуса на пункт указанного индекса, в ListBox с множественным выбором

#include <GuiListBox.au3>
_GUICtrlListBox_SetCaretIndex($hWnd, $iIndex [, $fPartial = False])

Параметры

$hWnd Дескриптор или идентификатор элемента
$iIndex Индекс пункта, отсчёт от 0
$fPartial [необязательный] Если False, то пункт прокручивается, пока не будет полностью видимым. Если True, то пункт прокручивается, пока не будет видимым хотя бы частично.

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False

См. также

_GUICtrlListBox_GetCaretIndex

Пример

#include <GuiListBox.au3>
#include <GUIConstantsEx.au3>

$Debug_LB = False ; Проверяет ClassName передаваемый в ListBox функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()
    Local $iIndex, $hListBox

    ; Создаёт GUI
    GUICreate("Устанавливает прямоугольник фокуса", 400, 296)
    $hListBox = GUICtrlCreateList("", 2, 2, 396, 296)
    GUISetState()

    ; Добавляет строки
    _GUICtrlListBox_BeginUpdate($hListBox)
    For $iI = 1 To 9
        _GUICtrlListBox_AddString($hListBox, StringFormat("%03d : Рандомная строка", Random(1, 100, 1)))
    Next
    _GUICtrlListBox_EndUpdate($hListBox)

    ; Устанавливает прямоугольник фокуса
    _GUICtrlListBox_SetCaretIndex($hListBox, 2)

    ; Получает прямоугольник фокуса
    $iIndex = _GUICtrlListBox_GetCaretIndex($hListBox)
    _GUICtrlListBox_SetCurSel($hListBox, $iIndex)

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main