Функция _GUICtrlListBox_GetSelItemsText

         Описание функции

_GUICtrlListBox_GetSelItemsText

Возвращает текст выделенных пунктов

#include <GuiListBox.au3>
_GUICtrlListBox_GetSelItemsText($hWnd)

Параметры

$hWnd Дескриптор или идентификатор элемента

Возвращаемое значение

Успех: Возвращает массив следующего формата:
        [0] - Общее количество элементов в массиве
        [1] - Текст выделенного пункта
        [2] - Текст выделенного пункта
        [n] - Текст выделенного пункта

См. также

_GUICtrlListBox_GetSelItems

Пример

#include <GuiListBox.au3>
#include <GUIConstantsEx.au3>

$Debug_LB = False ; Проверяет ClassName передаваемый в ListBox функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()
    Local $sItems, $aItems, $hListBox

    ; Создаёт GUI
    GUICreate("Получает текст выделенных пунктов", 400, 296)
    $hListBox = GUICtrlCreateList("", 2, 2, 396, 296, BitOR($LBS_STANDARD, $LBS_EXTENDEDSEL))
    GUISetState()

    ; Добавляет строки
    _GUICtrlListBox_BeginUpdate($hListBox)
    For $iI = 1 To 9
        _GUICtrlListBox_AddString($hListBox, StringFormat("%03d : Рандомная строка", Random(1, 100, 1)))
    Next
    _GUICtrlListBox_EndUpdate($hListBox)

    ; Выделяет несколько элементов
    _GUICtrlListBox_SetSel($hListBox, 3)
    _GUICtrlListBox_SetSel($hListBox, 4)
    _GUICtrlListBox_SetSel($hListBox, 5)

    ; Получает текст выделенных пунктов
    $aItems = _GUICtrlListBox_GetSelItemsText($hListBox)
    For $iI = 1 To $aItems[0]
        $sItems &= @LF & $aItems[$iI]
    Next
    MsgBox(4160, "Информация", "Текст выделенных пунктов: " & $sItems)

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main