Функция _GUICtrlListBox_SetSel

         Описание функции

_GUICtrlListBox_SetSel

Выделяет строку(и) в списке с множественным выбором

#include <GuiListBox.au3>
_GUICtrlListBox_SetSel($hWnd [, $iIndex = -1 [, $fSelect = -1]])

Параметры

$hWnd Дескриптор или идентификатор элемента
$iIndex [необязательный] Индекс пункта, отсчёт от 0
$fSelect [необязательный] -1 - устанавливает выделение, 0 - убирает выделение.

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False

Примечания

При $iIndex равным -1 означает переключить (инвертировать) выделенные/невыделенные всех пунктов ($fSelect при этом игнорируется)

См. также

_GUICtrlListBox_GetSel

Пример

#include <GuiListBox.au3>
#include <GUIConstantsEx.au3>

$Debug_LB = False ; Проверяет ClassName передаваемый в ListBox функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()
    Local $hListBox

    ; Создаёт GUI
    GUICreate("Выделяет строку(и)", 400, 296)
    $hListBox = GUICtrlCreateList("", 2, 2, 396, 296, BitOR($LBS_STANDARD, $LBS_EXTENDEDSEL))
    GUISetState()

    ; Добавляет строки
    _GUICtrlListBox_BeginUpdate($hListBox)
    For $iI = 1 To 9
        _GUICtrlListBox_AddString($hListBox, StringFormat("%03d : Рандомная строка", Random(1, 100, 1)))
    Next
    _GUICtrlListBox_EndUpdate($hListBox)

    ; Выделяет несколько элементов
    _GUICtrlListBox_SetSel($hListBox, 3)
    _GUICtrlListBox_SetSel($hListBox, 4)
    _GUICtrlListBox_SetSel($hListBox, 5)

    ; Получает состояние выбранного пункта
    MsgBox(4160, "Информация", "Выделен 5-ый пункт: " & _GUICtrlListBox_GetSel($hListBox, 4))

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main