Функция _GUICtrlHeader

Функция _GUICtrlHeader_GetItemFormat

_GUICtrlHeader_GetItemFormat

Возвращает формат пункта

#include <GuiHeader.au3>
_GUICtrlHeader_GetItemFormat($hWnd, $iIndex)

Параметры

$hWnd	Дескриптор элемента
$iIndex	Индекс пункта, отсчёт от 0

Возвращаемое значение

Успех: Возвращает формат пункта в виде комбинации следующих идентификаторов формата:
        $HDF_CENTER - Текст пункта выравнивается по центру
        $HDF_LEFT - Текст пункта выравнивается по левому краю
        $HDF_RIGHT - Текст пункта выравнивается по правому краю
        $HDF_BITMAP - Пункт отображает bitmap
        $HDF_BITMAP_ON_RIGHT - bitmap находится справа от текста
        $HDF_OWNERDRAW - Владелец элемента Header рисует пункт
        $HDF_STRING - Пункт отображает строку
        $HDF_IMAGE - Отображает изображение из списка изображений
        $HDF_RTLREADING - Текст будет читаться в противоположном направлении от текста в родительском окне
        $HDF_SORTDOWN - Рисует стрелку вниз на этом пункте (Windows XP и выше)
        $HDF_SORTUP - Рисует стрелку вверх на этом пункте (Windows XP и выше)

См. также

_GUICtrlHeader_SetItemFormat

Пример

#include <GUIConstantsEx.au3>
#include <GuiHeader.au3>
#include <GuiImageList.au3>
#include <WinAPI.au3>

$Debug_HDR = False ; Проверяет ClassName передаваемый в функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

Global $iMemo

_Main()

Func _Main()
Local $hGUI, $hHeader, $hImage

; Создаёт GUI
$hGUI = GUICreate(StringTrimRight(@ScriptName, 4), 400, 300)
$hHeader = _GUICtrlHeader_Create ($hGUI)
_GUICtrlHeader_SetUnicodeFormat ($hHeader, True)
$iMemo = GUICtrlCreateEdit("", 2, 24, 396, 274, 0)
GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
GUISetState()

; Создаёт список изображений с изображениями
$hImage = _GUIImageList_Create (11, 11)
_GUIImageList_Add ($hImage, _WinAPI_CreateSolidBitmap ($hGUI, 0xFF0000, 11, 11))
_GUIImageList_Add ($hImage, _WinAPI_CreateSolidBitmap ($hGUI, 0x00FF00, 11, 11))
_GUIImageList_Add ($hImage, _WinAPI_CreateSolidBitmap ($hGUI, 0x0000FF, 11, 11))
_GUICtrlHeader_SetImageList ($hHeader, $hImage)

; Добавляет колонки
_GUICtrlHeader_AddItem ($hHeader, "Колонка 1", 100, 0, 0)
_GUICtrlHeader_AddItem ($hHeader, "Колонка 2", 100, 0, 1)
_GUICtrlHeader_AddItem ($hHeader, "Колонка 3", 100, 0, 2)
_GUICtrlHeader_AddItem ($hHeader, "Колонка 4", 100)

; Устанавливает формат 1-ой колонки
_GUICtrlHeader_SetItemFormat ($hHeader, 0, BitOR($HDF_CENTER, $HDF_STRING))

; Показывает формат 1-ой колонки
MemoWrite("Формат 1-ой колонки: " & "0x" & Hex(_GUICtrlHeader_GetItemFormat ($hHeader, 0)))

Sleep(1000)

; Устанавливает формат 1-ой колонки
_GUICtrlHeader_SetItemFormat ($hHeader, 0, BitOR($HDF_LEFT, $HDF_STRING, $HDF_IMAGE))

; Показывает формат 1-ой колонки
MemoWrite("Формат 1-ой колонки: " & "0x" & Hex(_GUICtrlHeader_GetItemFormat ($hHeader, 0)))

; Цикл выполняется, пока окно не будет закрыто
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc ;==>_Main

; Записывает строку в элемент для заметок
Func MemoWrite($sMessage)
GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc ;==>MemoWrite