Функция _GUICtrlEdit_LineScroll

         Описание функции

_GUICtrlEdit_LineScroll

Прокручивает текст

#include <GuiEdit.au3>
_GUICtrlEdit_LineScroll($hWnd, $iHoriz, $iVert)

Параметры

$hWnd Дескриптор или идентификатор элемента
$iHoriz Количество символов для прокрутки по горизонтали.
$iVert Количество строк для прокрутки по вертикали.

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False

Примечания

Элемент не прокручивается по вертикали после последней строки текста в окне редактирования.

Если текущая строка плюс количество строк указанных в параметре $iVert превышает общее количество строк в окне редактирования, то значение корректируется так, чтобы последняя строка переместилась в верхнюю часть окна редактирования.

_GUICtrlEdit_LineScroll прокручивает текст по вертикали или по горизонтали.
_GUICtrlEdit_LineScroll можно использоваться для горизонтальной прокрутки к последнему символу любой строки.

См. также

_GUICtrlEdit_Scroll

Пример

#include <GuiEdit.au3>
#include <GuiStatusBar.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

$Debug_Ed = False ; Проверяет ClassName передаваемый в Edit функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()
    Local $hStatusBar, $hEdit, $hGUI, $sText

    ; Создаёт GUI
    $hGUI = GUICreate("Прокручивает текст", 400, 300)
    $hEdit = GUICtrlCreateEdit("", 2, 2, 394, 268, BitOR($ES_WANTRETURN, $WS_VSCROLL))
    $hStatusBar = _GUICtrlStatusBar_Create($hGUI)
    GUISetState()

    ; Устанавливает текст
    For $i = 1 To 50
        $sText &= $i & @CRLF
    Next
    _GUICtrlEdit_SetText($hEdit, $sText)

    ; Прокрутка к последней строке
    _GUICtrlStatusBar_SetText($hStatusBar, "Прокручено: " & _GUICtrlEdit_LineScroll($hEdit, 0, _GUICtrlEdit_GetLineCount($hEdit)))

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main