Функция _GUICtrlEdit_GetLineCount

         Описание функции

_GUICtrlEdit_GetLineCount

Возвращает количество строк

#include <GuiEdit.au3>
_GUICtrlEdit_GetLineCount($hWnd)

Параметры

$hWnd Дескриптор или идентификатор элемента

Возвращаемое значение

Успех:Возвращает общее количество строк текста
Ошибка:Возвращает 1

Примечания

Если элемент управления не содержит текста, возвращается значение 1.
Возвращаемое значение никогда не будет меньше 1.

Функция _GUICtrlEdit_GetLineCount возвращает общее количество строк текста, а не количество видимых строк.

Если установлен стиль - перенос строк, то количество строк может иметь другое значение при изменении размера окна редактирования.

Пример

#include <GuiEdit.au3>
#include <GuiStatusBar.au3>
#include <GUIConstantsEx.au3>

$Debug_Ed = False ; Проверяет ClassName передаваемый в Edit функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()
    Local $hStatusBar, $hEdit, $hGUI
    Local $sWow64 = ""
    If @AutoItX64 Then $sWow64 = "\Wow6432Node"
    Local $sFile = RegRead("HKEY_LOCAL_MACHINE\SOFTWARE" & $sWow64 & "\AutoIt v3\AutoIt", "InstallDir") & "\include\_ReadMe_.txt"

    ; Создаёт GUI
    $hGUI = GUICreate("Количество строк", 400, 300)
    $hEdit = GUICtrlCreateEdit("", 2, 2, 394, 268)
    $hStatusBar = _GUICtrlStatusBar_Create($hGUI, -1)
    GUISetState()

    _GUICtrlEdit_SetText($hEdit, FileRead($sFile))
    _GUICtrlStatusBar_SetText($hStatusBar, @TAB & "Строк: " & _GUICtrlEdit_GetLineCount($hEdit))
    _GUICtrlStatusBar_SetIcon($hStatusBar, 0, 97, "shell32.dll")

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main