Функция _GUICtrlComboBox_SetEditText

         Описание функции

_GUICtrlComboBox_SetEditText

Устанавливает текст в поле редактирования ComboBox без добавления в список.

#include <GuiComboBox.au3>
_GUICtrlComboBox_SetEditText($hWnd, $sText)

Параметры

$hWnd Дескриптор или идентификатор элемента
$sText Текст

Примечания

Минимальная OS - Windows XP.
Если сообщение высылается в ComboBox со стилем $CBS_DROPDOWN или $CBS_DROPDOWNLIST, то функция потерпит неудачу.

См. также

_GUICtrlComboBox_GetEditText, _GUICtrlComboBox_ReplaceEditSel

Пример

#include <GuiComboBox.au3>
#include <GUIConstantsEx.au3>

$Debug_CB = False ; Проверяет ClassName передаваемый в ComboBox/ComboBoxEx функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

Global $iMemo

_Main()

Func _Main()
    Local $hCombo

    ; Создаёт GUI
    GUICreate("Устанавливает текст в поле ввода", 400, 296)
    $hCombo = GUICtrlCreateCombo("", 2, 2, 396, 296)
    $iMemo = GUICtrlCreateEdit("", 2, 32, 396, 266, 0)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    ; Добавляет файлы
    _GUICtrlComboBox_BeginUpdate($hCombo)
    _GUICtrlComboBox_AddDir($hCombo, @WindowsDir & "\*.exe")
    _GUICtrlComboBox_EndUpdate($hCombo)

    ; Устанавливает текст в поле ввода
    _GUICtrlComboBox_SetEditText($hCombo, StringFormat("%d - Какой-то новый текст", Random(1, 20, 1)))

    ; Получает текст из поля ввода
    MemoWrite("Текст из поля ввода: " & _GUICtrlComboBox_GetEditText($hCombo))

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main

; Записывает строку в элемент для заметок
Func MemoWrite($sMessage)
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite