Функция _GUICtrlComboBox_ReplaceEditSel

         Описание функции

_GUICtrlComboBox_ReplaceEditSel

Заменяет текст, выделенный в поле ввода

#include <GuiComboBox.au3>
_GUICtrlComboBox_ReplaceEditSel($hWnd, $sText)

Параметры

$hWnd Дескриптор или идентификатор элемента
$sText Строка, содержащая текст замены

Примечания

Минимальная OS - Windows XP.
Если сообщение высылается в ComboBox со стилем $CBS_DROPDOWN или $CBS_DROPDOWNLIST, то функция потерпит неудачу.

См. также

_GUICtrlComboBox_SetEditText, _GUICtrlComboBox_SetEditSel

Пример

#include <GuiComboBox.au3>
#include <GUIConstantsEx.au3>

$Debug_CB = False ; Проверяет ClassName передаваемый в ComboBox/ComboBoxEx функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()
    Local $hCombo

    ; Создаёт GUI
    GUICreate("Заменяет текст, выделенный в поле ввода", 400, 296)
    $hCombo = GUICtrlCreateCombo("", 2, 2, 396, 296)
    GUISetState()

    ; Устанавливает текст в поле ввода
    _GUICtrlComboBox_SetEditText($hCombo, "Старый текст")

    ; Добавляет файлы
    _GUICtrlComboBox_BeginUpdate($hCombo)
    _GUICtrlComboBox_AddDir($hCombo, @WindowsDir & "\*.exe")
    _GUICtrlComboBox_EndUpdate($hCombo)

    Sleep(500)

    ; Выделяет текст в поле ввода
    _GUICtrlComboBox_SetEditSel($hCombo, 0, -1)

    Sleep(500)

    ; Заменяет текст, выделенный в поле ввода
    _GUICtrlComboBox_ReplaceEditSel($hCombo, "Новый текст")

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main