Функция _GUICtrlComboBox_GetListArray

         Описание функции

_GUICtrlComboBox_GetListArray

Возвращает все пункты из списка ComboBox в виде массива

#include <GuiComboBox.au3>
_GUICtrlComboBox_GetListArray($hWnd)

Параметры

$hWnd Дескриптор или идентификатор элемента

Возвращаемое значение

Успех: Возвращает массив следующего формата:
        [0] - Количество пунктов
        [1] - Пункт 1
        [2] - Пункт 2
        [n] - Пункт n

См. также

_GUICtrlComboBox_GetList

Пример

#include <GuiComboBox.au3>
#include <GUIConstantsEx.au3>
#include <Constants.au3>

$Debug_CB = False ; Проверяет ClassName передаваемый в ComboBox/ComboBoxEx функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

Global $iMemo

_Main()

Func _Main()
    Local $aList, $hCombo

    ; Создаёт GUI
    GUICreate("Получает все пункты из списка", 400, 296)
    $hCombo = GUICtrlCreateCombo("", 2, 2, 396, 296)
    $iMemo = GUICtrlCreateEdit("", 2, 32, 396, 266, 0)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    ; Добавляет диски
    _GUICtrlComboBox_AddDir($hCombo, "", $DDL_DRIVES, False)

    ; Получает все пункты из списка в массив
    $aList = _GUICtrlComboBox_GetListArray($hCombo)
    For $x = 1 To $aList[0]
        MemoWrite($aList[$x])
    Next

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main

; Записывает строку в элемент для заметок
Func MemoWrite($sMessage)
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite