Функция _GUICtrlComboBox_GetList

         Описание функции

_GUICtrlComboBox_GetList

Возвращает все пункты из списка ComboBox

#include <GuiComboBox.au3>
_GUICtrlComboBox_GetList($hWnd)

Параметры

$hWnd Дескриптор или идентификатор элемента

Возвращаемое значение

Успех: Возвращает строку со всеми пунктами ComboBox.

Примечания

По умолчанию используется разделитель "|", но это можно изменить с помощью Opt("GUIDataSeparatorChar", "Новый разделитель")

См. также

_GUICtrlComboBox_GetListArray

Пример

#include <GuiComboBox.au3>
#include <GUIConstantsEx.au3>
#include <Constants.au3>

$Debug_CB = False ; Проверяет ClassName передаваемый в ComboBox/ComboBoxEx функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

Global $iMemo

_Main()

Func _Main()
    Local $aList, $hCombo
    Opt("GUIDataSeparatorChar", ",") ; устанавливает разделитель

    ; Создаёт GUI
    GUICreate("Получает все пункты из списка", 400, 296)
    $hCombo = GUICtrlCreateCombo("", 2, 2, 396, 296)
    $iMemo = GUICtrlCreateEdit("", 2, 32, 396, 266, 0)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    ; Добавляет диски
    _GUICtrlComboBox_AddDir($hCombo, "", $DDL_DRIVES, False)

    ; Получает все пункты из списка
    $aList = StringSplit(_GUICtrlComboBox_GetList($hCombo), ",")
    For $x = 1 To $aList[0]
        MemoWrite($aList[$x])
    Next

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main

; Записывает строку в элемент для заметок
Func MemoWrite($sMessage)
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite